удалить строки из файла, разбиваются на несколько строк с «\»

Question

Я хочу, чтобы удалить строки из файла на основе строки я ищу, как это:

sed -i.bak '/xyz/d' "$PATH" 

Проблема для меня являются строки, которые содержат эту строку и разбиты на несколько строк с «\», например:

this is the string im looking for xyz but there \ 
    are other lines \ 
    that are part \ 
    of that \ 
    god damn line 

есть простой способ, чтобы полностью удалить «линию» с Башем/SED/регулярным выражением?

Answer 1

Вы могли бы сказать: (. Это присоединится к строке, содержащей xyz, который разделен на несколько строк, заканчивающиеся в /, а затем удалить его)

sed -e :a -e '/.*xyz.*\\$/N; s/\\\n//; ta' -e '/xyz/d' filename 

Answer 2

Поскольку sed работает по одной линии за раз, вам нужно будет использовать команду N, чтобы присоединиться к линиям.

Это сообщение объясняет использование довольно хорошо: How the 'N' command works in sed?

Answer 3

Это может работать для вас (GNU СЭД):

sed ':a;/\\$/{N;ba};h;s/\\\n//g;/xyz/d;g' file 

Это собирает несколько строк, копирует их в пространство удержания, удаляет маркеры разделительной линии, а затем удаляет всю строку, если она содержит xyz. Если строка не содержит xyz, оригинальные разделительные линии заменяются и распечатываются.

Если предпочтительно, чтобы все несколько линий объединяются независимо, то:

sed ':a;/\\$/{N;ba};s/\s*\\\n\s*/ /g;/xyz/d' file