Как сделать пакет в Ada универсальным пакетом?

Question

У меня есть программа Ada для вычисления среднего и стандартного отклонения 200 значений, взятых из файла, и они оба работают правильно. эти пакеты имеют тип float, как превратить их в общий тип?

Средний пакет объявления файла:

with Text_IO; 
package avg is 
    type int_array is Array (1..200) of integer; 
    function avrage (ParArray: int_array) return float; 
end avg; 

и среднее тело пакета:

with Text_IO; 
WITH Ada.Integer_Text_IO; USE Ada.Integer_Text_IO; 
package body avg is 
function avrage (ParArray: int_array) return float is 
    result: float :=0.0; 
    final:float :=0.0; 
    myarray: int_array:=ParArray; 
begin 
    for v in myarray'Range loop 
    result:= result + float(myarray(v)); 
    end loop; 
    final:=result/200.0; 
    return final; 
end avrage; 
end avg; 

Я называю этот пакет в моей основной программе, «с» и «использовать». пожалуйста, скажите мне, что делать

Answer 1

Вы не говорите, что хотите, чтобы ваш пакет был общим в.

Я предполагаю, что вы хотите, чтобы вход будет массив (Input_Values ниже) некоторого типа Input_Value индексируется Input_Index, и вы хотите, чтобы вывод, что какая-то типа с плавающей точкой Result_Value. Вам понадобится функция To_Result_Value для преобразования Input_Value в Result_Value.

generic 
    type Input_Value is private; 
    type Input_Index is (<>); 
    type Input_Values is array (Input_Index range <>) of Input_Value; 
    type Result_Value is digits <>; 
    with function To_Result_Value (X : Input_Value) return Result_Value; 
package Statistics is 
    function Mean (Input : Input_Values) return Result_Value; 
end Statistics; 

... с реализацией:

package body Statistics is 
    function Mean (Input : Input_Values) return Result_Value is 
     Sum : Result_Value := 0.0; 
    begin 
     for I of Input loop 
     Sum := Sum + To_Result_Value (I); 
     end loop; 
     return Sum/Result_Value (Input’Length); 
    end Mean; 
end Statistics; 

... и немного демо:

with Ada.Text_IO; 
with Statistics; 
procedure Demo is 
    type Arr is array (Integer range <>) of Integer; 
    function To_Float (X : Integer) return Float is 
    begin 
     return Float (X); 
    end To_Float; 
    package Avg is new Statistics (Input_Value => Integer, 
            Input_Index => Integer, 
            Input_Values => Arr, 
            Result_Value => Float, 
            To_Result_Value => To_Float); 
    A : Arr := (1, 2, 3, 4, 5); 
    M : Float; 
begin 
    M := Avg.Mean (A); 
    Ada.Text_IO.Put_Line ("mean is " & Float'Image (M)); 
end Demo;