введите значение перед запуском cmd?

Question

Ни в коем случае не скриптер, но задавался вопросом, как создать командный файл (.cmd), где я могу ввести значение или предпочтительно выбрать из меню при выполнении файла.

start.cmd файл запускает программу «minerd» с аргументами: результатам сделанной

minerd -a scrypt -o stratum+tcp://us-east.multipool.us:3357 -O user:pass -q 

Единственное, что я хотел бы, чтобы выбрать из меню номер порта. Номер порта определяет, какую криптовую валюту я бы хотел добыть.

вот некоторые, как, например:

Multipool:7777 
DigitalCoin (DGC):3343 
NovaCoin (NVC):3344 
LuckyCoin (LKY):3345 
Argentum (ARG):3346 
PhenixCoin (PXC):3347 
and more.... 

было бы неплохо иметь меню показать название валюты вместо номера порта. Но это не обязательно.

Что было бы лучшим способом сделать это?

С уважением

Answer 1

Сохранить как miner.bat и запустить его: (дополнительный вариант добавляется для одного URL)

@:Single URL:0000 
@:Multipool:7777 
@:DigitalCoin (DGC):3343 
@:NovaCoin (NVC):3344 
@:LuckyCoin (LKY):3345 
@:Argentum (ARG):3346 
@:PhenixCoin (PXC):3347 
@echo off 
:start 
set "var=@" 
for /f "tokens=1,2 delims=:@" %%a in ('findstr /n "%var%:" "%~f0" ') do (
echo %%a %%b 
) 
echo. 
set /p "num=Select a number: " 
for /f "tokens=1,2,3 delims=:@" %%a in ('findstr /n "%var%:" "%~f0" ^|findstr "^%num%:" ') do (
set "name=%%b" 
set "port=%%c" 
) 
echo starting %name%:%port% 
title Mining "%name%" 
if %port% EQU 0000 (
    minerd -a scrypt -o stratum+tcp://specialURLhere -O user:pass -q 
) else (
    minerd -a scrypt -o stratum+tcp://us-east.multipool.us:%port% -O user:pass -q 
)