Нужно удалить числа в круглых скобках и круглых скобках

У меня есть таблица, в которой столбец содержит строковые данные (имена), за которыми следуют цифры в круглых скобках; т. е. (9815536). Эти числа не являются постоянными по длине. Мне нужно избавиться от чисел в круглых скобках и круглых скобках. Я пробовал использовать Columns(). Cells.Replace funtion безрезультатно. Есть ли способ использовать регулярное выражение для этого? Пример из ячейки будет выглядеть следующим образом:Нужно удалить числа в круглых скобках и круглых скобках

Column A 
John Doe (9815536) 
Sam Smith (12906) 
...

код Я пытался выглядеть так:

Columns("A:A").Select 
    Selecton.Replace What:="\([0-9]*\), _ 
    Replacement:="", LookAt:=xlPart, SearchOrder:=xlByRows, _ 
    MatchCase:=False, SearchFormat:=False, _ 
    ReplaceFormat:=False

источник

2016-01-23 oldnewbie

Вы можете использовать простую формулу '= TRIM (ЛЕВЫЙ (A1, FIND ("(", A1) -1))' –

или цикл через столбец vba и использовать 'cell = trim (split (cell," (") (0))' были 'cell' является ссылкой. –

Если вы действительно хотите использовать регулярное выражение, вам нужно посмотреть [ЗДЕСЬ] (http://stackoverflow.com/questions/22542834/how-to-use-regular-expressions-regex-in-microsoft-excel-both-in-cell-and-loops) при правильном использовании. –

Быстрый способ осуществить это использовать

regexp

и вариант массива в VBA.

Использование кода на основе моей статьи Using Variant Arrays in Excel VBA for Large Scale Data Manipulation

Sub KillNumParen() 
Dim rng1 As Range 
Dim rngArea As Range 
Dim lngRow As Long 
Dim lngCol As Long 
Dim lngCalc As Long 
Dim objReg As Object 
Dim X() 


On Error Resume Next 
Set rng1 = Application.InputBox("Select range for the replacement of non-number", "User select", Selection.Address, , , , , 8) 
If rng1 Is Nothing Then Exit Sub 
On Error GoTo 0 

'See Patrick Matthews excellent article on using Regular Expressions with VBA 
Set objReg = CreateObject("vbscript.regexp") 
objReg.Pattern = "\(\d+\)" 
objReg.Global = True 

'Speed up the code by turning off screenupdating and setting calculation to manual 
'Disable any code events that may occur when writing to cells 
With Application 
    lngCalc = .Calculation 
    .ScreenUpdating = False 
    .Calculation = xlCalculationManual 
    .EnableEvents = False 
End With 

'Test each area in the user selected range 

'Non contiguous range areas are common when using SpecialCells to define specific cell types to work on 
For Each rngArea In rng1.Areas 
    'The most common outcome is used for the True outcome to optimise code speed 
    If rngArea.Cells.Count > 1 Then 
     'If there is more than once cell then set the variant array to the dimensions of the range area 
     'Using Value2 provides a useful speed improvement over Value. On my testing it was 2% on blank cells, up to 10% on non-blanks 
     X = rngArea.Value2 
     For lngRow = 1 To rngArea.Rows.Count 
      For lngCol = 1 To rngArea.Columns.Count 
       'replace the leading zeroes 
       X(lngRow, lngCol) = objReg.Replace(X(lngRow, lngCol), vbNullString) 
      Next lngCol 
     Next lngRow 
     'Dump the updated array sans leading zeroes back over the initial range 
     rngArea.Value2 = X 
    Else 
     'caters for a single cell range area. No variant array required 
     rngArea.Value = objReg.Replace(rngArea.Value, vbNullString) 
    End If 
Next rngArea 

'cleanup the Application settings 
With Application 
    .ScreenUpdating = True 
    .Calculation = lngCalc 
    .EnableEvents = True 
End With 

Set objReg = Nothing 
End Sub

источник

2016-01-25 02:37:31 brettdj

Нужно удалить числа в круглых скобках и круглых скобках

ответ

Смежные вопросы