Windows-скрипт для удаления всего, кроме расширения файлов изображений

Question

Я хочу создать сценарий в Windows 7, чтобы удалить все в директории, которая не является изображением. Так

for all files in directory X 

    if file y does not have extension in (.png, .gif, .jpeg) 

    delete y 

    end 

это его

как я могу найти или создать такой скрипт

заметь, некоторые изображения являются важными, так что этот сценарий должен работать правильно :) Я не думаю, Я должен экспериментировать здесь, и даже если бы я протестировал свой собственный скрипт в небольшой директории с экспериментальными файлами, я не уверен, что я должен попробовать.

У меня есть этот код, как предложил:

::extensions are delimited with space // filename is del_stuff.bat 

set "extensions_list=.png .gif .jpeg .bmp .jpg " 
pushd "C:\Users\denman\Desktop\xxx\" 
for /f "delims=" %%f in ('dir /b ^|findstr /i /e /v "%extensions_list%" ') do (
     echo del /q /f "%%~f" 
) 
popd 

Но я получаю эту ошибку:

Answer 1

@echo off 
::extensions are delimited with space 
set "extensions_list=.png .gif .jpeg " 
pushd "C:\Directory_with_pictures" && (
    for /f "delims=" %%f in ('dir /b /a-d ^|findstr /i /e /v "%extensions_list%" ') do (
     echo del /q /f "%%~f" 
    ) 
    popd 
) 

'эхо' является для проверки результата .Снять эхо активировать удаление. И изменить "C:\Directory_with_pictures" с фактическим путем.

EDIT тестирование сценария:

@echo off 

md test_dir>nul 2>&1 
echo #>test_dir\t1.png 
echo #>test_dir\t1.txt 
echo #>test_dir\t1.tst 
echo #>test_dir\t1.jpg 
echo #>test_dir\t1.gif 

echo #>test_dir\t2.png 
echo #>test_dir\t2.txt 
echo #>test_dir\t2.tst 
echo #>test_dir\t2.jpg 
echo #>test_dir\t2.gif 

echo -- before deleting-- 
dir /b .\test_dir\* 
echo(
echo(

::extensions are delimited with space 
set "extensions_list=.png .gif .jpeg .jpg" 


pushd "test_dir" 
for /f "delims=" %%f in ('dir /b ^|findstr /i /e /v "%extensions_list%" ') do (
     del /q /f "%%~f" 
) 
popd 

echo -- after deleting -- 
dir /b .\test_dir\* 

Выход:

-- before deleting-- 
t1.gif 
t1.jpg 
t1.png 
t1.tst 
t1.txt 
t2.gif 
t2.jpg 
t2.png 
t2.tst 
t2.txt 


-- after deleting -- 
t1.gif 
t1.jpg 
t1.png 
t2.gif 
t2.jpg 
t2.png 

Answer 2

Использование Powershell, вы можете получить список файлов, вам нужно что-то вроде этого:

Get-ChildItem | where {!$_.PsIsContainer -and !(@(".png",".gif",".jpeg") -contains $_.Extension) } 

Я оставил команду Delete, убедитесь, что t он возвращает правильные результаты, прежде чем вы это сделаете.