Код VBA, чтобы открыть меняющееся имя файла

Question

Я пытаюсь найти строку кода, чтобы открыть файл. Путь постоянен, то есть

"H:\silly\goose\*filename.xlsm*" 

Однако это имя файла будет меняться каждый раз, когда я пытаюсь запустить этот макрос. Это связано с тем, что я буду использовать этот макрос для автоматизации отчета, который я запускаю еженедельно. Каждый отчет сохраняется с датой заголовка, и все отчеты хранятся в одной и той же папке, то есть я не могу просто начать их именовать. Примеры:

H: \ глупой \ гусь \ Report 06-03-15.xlsm
H: \ глупой \ гусь \ Report 05-27-15.xlsm

Единственные помогает Информация состоит в том, что этот отчет должен запускаться каждую среду. Поэтому каждое имя файла будет иметь разницу в 7 дней. Я не знаю, есть ли что-нибудь, что я могу сделать с помощью метода Date.

Answer 1

This reference имеет эту функцию:

Function GetFileList(FileSpec As String) As Variant 
' Returns an array of filenames that match FileSpec 
' If no matching files are found, it returns False 

    Dim FileArray() As Variant 
    Dim FileCount As Integer 
    Dim FileName As String 

    On Error GoTo NoFilesFound 

    FileCount = 0 
    FileName = Dir(FileSpec) 
    If FileName = "" Then GoTo NoFilesFound 

' Loop until no more matching files are found 
    Do While FileName <> "" 
     FileCount = FileCount + 1 
     ReDim Preserve FileArray(1 To FileCount) 
     FileArray(FileCount) = FileName 
     FileName = Dir() 
    Loop 
    GetFileList = FileArray 
    Exit Function 

' Error handler 
NoFilesFound: 
    GetFileList = False 
End Function 

Теперь вы можете сделать:

p = "H:\silly\goose\*.xlsm" 
x = GetFileList(p) 

И получить файл, который вы хотите

Answer 2

Что вам нужно сделать, это заново построить свое имя файла первый.

Const fpath As String = "H:\silly\goose\" ' your fixed folder 
Dim fname As String 

' Below gives you the Wednesday of the week 
fname = Format(Date - (Weekday(Date) - 1) + 3, "mm-dd-yy") ' returns 06-03-15 if run today 
fname = "Report " & fname & ".xlsm" ' returns Report 06-03-15.xlsm 
fname = fpath & fname ' returns H:\silly\goose\Report 06-03-15.xlsm 

Затем выполнить открытие файла:

Dim wb As Workbook 
Set wb = Workbooks.Open(fname) 
If wb Is Nothing Then MsgBox "File does not exist": Exit Sub 

' Rest of your code goes here which works on wb Object