Разрешить переменную макроса в SAS

Question

У меня вопрос о разрешении макропеременных в SAS. У меня есть следующий код, который является упрощенной версией гораздо большего блока. По практической причине я не могу изменить структуру кода.

%let a = x1 x2 x3; 
%let b = y1 y2 y3; 
%let c = a b; 


%macro test (input); 
    %local i; 
    %let string_c = %str(&input); 
    %do i=1 %to 2; 
     %put &%qscan(&string_c, &i); /* ? */ 
    %end; 
%mend test; 

%test(&c); 

В шаге? выше, я хотел бы решить и б, как макропеременные и имею системную распечатку

x1 x2 x3 

и затем

y1 y2 y3 

Однако приведенный выше код не reslove а и Ь, как макропеременные и система распечатывает

&a 
&b 

Мне интересно, есть ли какие-либо решения этой проблемы.

Большое спасибо!

Answer 1

Попробуйте это:

%let a = x1 x2 x3; 
%let b = y1 y2 y3; 
%let c = a b; 

%macro test (input); 
    %local i; 
    %let string_c =%str(&input); 
    %do i=1 %to 2; 
     %put %unquote(&&%qscan(&string_c, &i)); 
    %end; 
%mend test; 

%test(&c); 

Answer 2

Триггер & предназначен для разрешения имени, но вы использовали другой макрос триггер% вместо имени. Так оно и не делает. Легче назначить имя макрокоманде, а затем оценить ее.

%macro test(list); 
    %local i varname value; 
    %do i=1 %to %sysfunc(countw(&list,%str())); 
    %let varname=%scan(&list,&i,%str()); 
    %let value=&&&varname ; 
    %put The value of "&varname" is "&value" ; 
    %end; 
%mend test; 
%let a=One ; 
%let b=Two ; 
%test(a b); 

Какие результаты в:

The value of "a" is "One" 
The value of "b" is "Two"