VBA Excel - ошибка приложения или объекта с = HYPERLINK

Question

У меня проблема с гиперссылкой на основе VBA в Excel 2016. Я хочу добавить лист «Навигация» перед всеми другими листами, но у меня есть проблема с " = HYPERLINK». Мой код выглядит следующим образом:

Dim wbBook As workbook 

Dim wsActive As Worksheet 
Dim wsSheet As Worksheet 

Dim lnRow As Long 
Dim lnPages As Long 
Dim lnCount As Long 

Dim temp As Variant 

Set wbBook = ActiveWorkbook 

wbBook.Sheets.Add(Before:=Worksheets(1)).Name = "Navigation" 

Set wsActive = wbBook.ActiveSheet 

With wsActive 
    .Name = "Navigation" 
    With .Range("A1:A1") 
     .Value = VBA.Array("Mitarbeiter") 
     .Font.Bold = True 
    End With 
End With 

lnRow = 2 
lnCount = 1 

For Each wsSheet In wbBook.Worksheets 
    If wsSheet.Name <> wsActive.Name Then 
     wsSheet.Activate 
     With wsActive 
      Worksheets("Navigation").Cells(lnRow, 1).Formula = _ 
      "=HYPERLINK(" & Chr(34) & "#" & "'" & wsSheet.Name & "'" & "!A" & lnRow & Chr(34) & ";" & Chr(34) & wsSheet.Name & Chr(34) & ")"  
     End With 
     lnRow = lnRow + 1 
     lnCount = lnCount + 1 
    End If 
Next wsSheet 

У меня есть проблема в том, что, когда я добавить знак «=» перед HYPERLINK, ошибка «Anwendungs- Одер objektorientierter Fehler» (приложение или ориентированная ошибка объекта) всплывает. Если я запускаю макрос без «=», программа работает, но мне нужно вручную добавить знак равенства в навигационный лист.

Приветствия заранее!

Answer 1

Поскольку вы уже используете VBA, почему бы не использовать возможности VBA для добавления гиперссылок (с помощью .Hyperlinks.Add).

Вы можете прочитать об этом больше на MSDN

я уменьшил использование в ActiveSheet и Activate.

Код

Option Explicit 

Sub TestHyperlink() 

Dim wbBook As Workbook 
Dim wsActive As Worksheet 
Dim wsSheet As Worksheet 

Dim lnRow As Long 
Dim lnPages As Long 
Dim lnCount As Long 
Dim temp As Variant 

Set wbBook = ActiveWorkbook 
Set wsActive = wbBook.Sheets.Add(Before:=Worksheets(1)) 
With wsActive 
    .Name = "Navigation" 
    With .Range("A1:A1") 
     .Value = VBA.Array("Mitarbeiter") 
     .Font.Bold = True 
    End With 
End With 

lnRow = 2 
lnCount = 1 

For Each wsSheet In wbBook.Worksheets 
    If wsSheet.Name <> wsActive.Name Then 
     With wsSheet 
      .Hyperlinks.Add Anchor:=Worksheets("Navigation").Range("A" & lnRow), _ 
       Address:="", SubAddress:="'" & .Name & "'!" & .Range("A" & lnRow).Address, _ 
       TextToDisplay:="#" & .Name 
     End With 
     lnRow = lnRow + 1 
     lnCount = lnCount + 1 
    End If 
Next wsSheet 

End Sub 

Answer 2

Попробуйте использовать запятую для разделения параметров формулы вместо запятой. Я думаю, что форсирование формул в таких клетках игнорирует локализацию.

With wsActive 
     Worksheets("Navigation").Cells(lnRow, 1).Formula = _ 
     "=HYPERLINK(" & Chr(34) & "#" & "'" & wsSheet.Name & "'" & "!A" & lnRow & Chr(34) & "," & Chr(34) & wsSheet.Name & Chr(34) & ")"  
    End With