XSLT Удалить начальные и конечные пробелы всех атрибутов

Question

Как создать идентичный XML-лист, но с удалением ведущих и завершающих пробелов каждого атрибута? (С использованием XSLT 2.0)

Go от этого:

<node id="DSN "> 
    <event id=" 2190 "> 
     <attribute key=" Teardown"/> 
     <attribute key="Resource "/> 
    </event> 
</node> 

Для этого:

<node id="DSN"> 
    <event id="2190"> 
     <attribute key="Teardown"/> 
     <attribute key="Resource"/> 
    </event> 
</node> 

Я полагаю, я бы предпочел, чтобы использовать функцию normalize-space(), но все работает.

Answer 1

normalize-space() не только удалит ведущие и конечные пробелы, но также установит один пробельный символ вместо последовательности последовательных пробельных символов.

Регулярное выражение может быть использовано для обработки только начальные и конечные пробельные символы:

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0"> 

    <xsl:template match="node()"> 
    <xsl:copy> 
     <xsl:apply-templates select="@*|node()"/> 
    </xsl:copy> 
    </xsl:template> 

    <xsl:template match="@*"> 
    <xsl:attribute name="{local-name()}" namespace="{namespace-uri()}"> 
     <xsl:value-of select="replace(., '^\s+|\s+$', '')"/> 
    </xsl:attribute> 
    </xsl:template> 

</xsl:stylesheet> 

Answer 2

Это следует сделать это:

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:output method="xml" indent="yes" omit-xml-declaration="yes"/> 

    <xsl:template match="node()"> 
    <xsl:copy> 
     <xsl:apply-templates select="@* | node()"/> 
    </xsl:copy> 
    </xsl:template> 

    <xsl:template match="@*"> 
    <xsl:attribute name="{name()}"> 
     <xsl:value-of select="normalize-space()"/> 
    </xsl:attribute> 
    </xsl:template> 
</xsl:stylesheet> 

Это также XSLT 1.0 совместимы.

При запуске на своем входе пробы, результат:

<node id="DSN"> 
    <event id="2190"> 
    <attribute key="Teardown" /> 
    <attribute key="Resource" /> 
    </event> 
</node> 

Одна вещь, чтобы отметить здесь, что normalize-space() превратит любой пробел в пределах значений атрибутов в единые пространства, так это:

<element attr=" this is an 
        attribute " /> 

бы быть изменен следующим образом:

<element attr="this is an attribute" /> 

Если вам нужно сохранить вес hitespace внутри значения as-is, тогда, пожалуйста, см. ответ Гюнтера.