Как удалить начальные и конечные пробелы из всех ячеек листа Excel одновременно

Question

У меня есть лист excel, который содержит много данных с ведущими и конечными пробелами.

Вручную удалять эти пространства с помощью TRIM() занимает много времени.

Как я могу сделать это эффективно.

Answer 1

Чтобы сделать это эффективно использовать вариантный массив, что-то вроде:

Sub VBATrim() 
    Dim rng1 As Range 
    Dim rngArea As Range 
    Dim lngRow As Long 
    Dim lngCol As Long 
    Dim lngCalc As Long 
    Dim X() 


    On Error Resume Next 
    Set rng1 = Application.InputBox("Select range for the replacement of non-number", "User select", Selection.Address, , , , , 8) 
    If rng1 Is Nothing Then Exit Sub 
    On Error GoTo 0 


    'Speed up the code by turning off screenupdating and setting calculation to manual 
    'Disable any code events that may occur when writing to cells 
    With Application 
     lngCalc = .Calculation 
     .ScreenUpdating = False 
     .Calculation = xlCalculationManual 
     .EnableEvents = False 
    End With 

    'Test each area in the user selected range 

    'Non contiguous range areas are common when using SpecialCells to define specific cell types to work on 
    For Each rngArea In rng1.Areas 
     'The most common outcome is used for the True outcome to optimise code speed 
     If rngArea.Cells.Count > 1 Then 
      'If there is more than once cell then set the variant array to the dimensions of the range area 
      'Using Value2 provides a useful speed improvement over Value. On my testing it was 2% on blank cells, up to 10% on non-blanks 
      X = rngArea.Value2 
      For lngRow = 1 To rngArea.Rows.Count 
       For lngCol = 1 To rngArea.Columns.Count 
        'replace the leading zeroes 
        X(lngRow, lngCol) = Trim(X(lngRow, lngCol)) 
       Next lngCol 
      Next lngRow 
      'Dump the updated array sans leading zeroes back over the initial range 
      rngArea.Value2 = X 
     Else 
      'caters for a single cell range area. No variant array required 
      rngArea.Value = Trim(rngArea.Value) 
     End If 
    Next rngArea 

    'cleanup the Application settings 
    With Application 
     .ScreenUpdating = True 
     .Calculation = lngCalc 
     .EnableEvents = True 
    End With 

End Sub 

Answer 2

Попробуйте этот небольшой макрос:

Sub KleanUp() 
    Dim r As Range 
    For Each r In ActiveSheet.UsedRange 
    v = r.Value 
    If v <> "" Then 
     If Not r.HasFormula Then 
     r.Value = Trim(v) 
     End If 
    End If 
    Next r 
End Sub 

Этот макрос не будет влиять на внутренние пространства или ячеек, содержащих формулы.