Создать временную диаграмму Excel

Question

Sub aaGraphing() 
' 
' aaGraphing Macro 
' 

' 
    Range("L948:W949,D948:D949").Select 
    Range("D949").Activate 
    ActiveSheet.Shapes.AddChart.Select 
    ActiveChart.ChartType = xlLineMarkers 
    ActiveChart.SetSourceData Source:=Range(_ 
     "Analytics!$L$948:$W$949,Analytics!$D$948:$D$949") 
End Sub 

Этот код создает диаграмму данных, которые я хочу. Есть ли способ сделать созданный график временным, чтобы при нажатии на любой уголок за пределами диаграммы он удаляется?

Answer 1

Обычный модуль .... код модуля

Option Explicit 


Public PlotName As String 
Public PlotRange As Range 


Sub Tester() 
AddPlot ActiveSheet.Range("B3:B7,D3:D7") 
End Sub 

Sub AddPlot(rng As Range) 
    With ActiveSheet.Shapes.AddChart 
     PlotName = .Name 
     .Chart.ChartType = xlLineMarkers 
     .Chart.SetSourceData Source:=Range(rng.Address()) 
    End With 
    Set PlotRange = rng 
    Application.EnableEvents=False  
    rng.Select 
    Application.EnableEvents=True 
End Sub 

Sub RemovePlot(rng As Range) 
    If Not PlotRange Is Nothing Then 
     If Application.Intersect(rng, PlotRange) Is Nothing Then 
      On Error Resume Next 
      rng.Parent.Shapes(PlotName).Delete 
      On Error GoTo 0 
     End If 
    End If 
End Sub 

Лист:

Private Sub Worksheet_SelectionChange(ByVal Target As Range) 
    RemovePlot Target 
End Sub 

Answer 2

Чтобы удалить диаграмму, вы можете использовать событие SelectionChange рабочего листа. Ниже я предполагаю, что есть только одна форма - диаграмма - которая может быть на листе.

Private Sub Worksheet_SelectionChange(ByVal Target As Range) 
    If Me.Shapes.Count = 1 Then 
     Me.Shapes(1).Delete 
    End If 
End Sub 

Возможно (я считаю), чтобы динамически присоединить это событие и удалить его. Тем не менее, я считаю, что это мало сложный.

Альтернативой может быть использование Application.OnTime, чтобы удалить его по истечении определенного периода времени.

Application.OnTime Now + TimeValue("00:00:40"), "ProcedureToDelete" 

через 40 секунд выполнит процедуру с названием «Процедура удаления». В этой процедуре вы можете убедиться, что выделение находится на рабочем листе, а не в диаграмме, которую вы собираетесь удалить.

Вы можете в установленном порядке проверить, выбран ли в данный момент график. Если нет, удалите его, иначе установите таймер еще раз.