Защитить все листы в рабочей книге

Question

Я хочу защитить все листы в книге на основе имени пользователя, поэтому книги будут защищены от внешнего использования, тогда как внутренне мы можем легко использовать. Тем не менее, код просто всегда заявляет, что линия Если ws.Protect = True Then является ложным, даже когда я знаю, лист защищен ...

Private Sub Workbook_Open() 
Dim strUser, Num, myCount, ws 

    strUser = CreateObject("WScript.Network").UserName 
    strUser = LCase(strUser) 
    Num = CLng(Right(strUser, 6)) 


    If Left(strUser, 1) = "D" And Len(strUser) = 11 And IsNumeric(Num) Then 
    For Each ws In ActiveWorkbook.Worksheets 
    If ws.Protect = True Then 
     ws.Unprotect "password" 
    Else 
     ws.Protect "password", DrawingObjects:=True, Contents:=True, _ 
         AllowSorting:=True, AllowFiltering:=True 
    End If 
    Next ws 
    End If 

End Sub 

любая помощь будет оценен по достоинству!

Answer 1

Вы должны смотреть на ProtectContents собственности, так

If ws.Protect = True Then должен быть If ws.ProtectContents = True Then

Answer 2

ws.protect является команда, чтобы защитить лист не проверить, если его защитой. Вы можете использовать

ActiveSheet.ProtectContents

ActiveSheet.ProtectDrawingObjects

activeSheet.ProtectScenarios

в вашем если заявления, чтобы проверить, если лист защищен в любой комбинации этих свойств.

Посмотрите здесь для получения дополнительной информации: https://support.microsoft.com/en-us/kb/161245

Answer 3

Я просто хочу прокомментировать, что ваше имя пользователя код проверки кажется, что он потерпит неудачу много:

Num = CLng(Right(strUser, 6)) это даст ошибку, если strUser не заканчивается 6 цифр.
Что вы хотите? IsNumeric(Right(strUser, 6))
На самом деле, даже не используйте IsNumeric, потому что, например, IsNumeric("1,234.56") вернет True.

Left(strUser, 1) = "D" это будет Ложное, потому что вы преобразовать strUset в нижний регистр с strUser = LCase(strUser) (если у вас нет Option Compare Text в начале файла)

Вы можете укоротить чек

Private Sub Workbook_Open() 
    Dim strUser$, ws As Worksheet 
    strUser = Environ$("UserName") 
    If Not strUser Like "[Dd]????######" Then Exit Sub ' ? matches any character, # matches any digit from 0 to 9, and [Dd] matches upper or lower case D 

    For Each ws In ActiveWorkbook.Worksheets 
     If ws.ProtectContents = True Then 
      ws.Unprotect "password" 
     Else 
      ws.Protect "password", DrawingObjects:=True, Contents:=True, _ 
        AllowSorting:=True, AllowFiltering:=True 
     End If 
    Next ws 
End Sub