Распечатайте все листы в книге, за исключением 3 конкретных листов

Question

Я хочу напечатать все листы в рабочей книге, в которой я работаю, за исключением трех конкретных листов под названием «Передняя страница», «Данные» и «Журналы». Я пробовал с «и» - и «или» -созданием и завернутыми круглыми скобками, и ничего не работало.

Вот код:

Sub printsheets() 
Dim ws As Worksheet 

    For Each ws In ActiveWorkbook.Worksheets 
     If ws.Name <> "Front Page" And _ 
      ws.Name <> "Data" And _ 
      ws.Name <> "Logs" Then 
      ws.PrintOut 
     End If 
    Next ws 

End Sub 

Answer 1

Похоже, что у вас есть скрытые листы в книге.

Перед тем, как распечатать их, вам необходимо отобразить их или проверить, скрыт ли рабочий лист. Либо вручную, либо (особенно если листы были скрыты программно с xlSheetVeryHidden):

ws.Visible = xlSheetVisible ' ADD THIS LINE TO UNHIDE A SHEET 
ws.PrintOut 

Или

If ws.Visible = xlSheetVisible Then 
    ws.PrintOut 
End if 

попробовать что-то вроде этого , если вы не хотите, чтобы распечатать скрытые листы:

Sub printsheets() 
Dim ws As Worksheet 
For Each ws In ActiveWorkbook.Worksheets 
    If ws.Visible = True Then 
    If ws.Name <> "Front Page" And _ 
    ws.Name <> "Data" And _ 
    ws.Name <> "Logs" Then 
     With ws.PageSetup 
     .PrintArea = "b2:g26" ' USE YOUR PRINTAREA 
     .Zoom = False 
     .FitToPagesTall = 1 
     .FitToPagesWide = 1 
     End With 
     ws.PrintOut 
    End If 
    End If 
Next ws 
End Sub 

Answer 2

Вы также можете использовать один список с листами, которые вы не хотите печатать

Sub printsheets() 
    Dim dontPrint As Object 
    Dim ws As Worksheet 
    Set dontPrint = CreateObject("Scripting.Dictionary") 

    dontPrint.Add "Front Page", 1 
    dontPrint.Add "Data", 2 
    dontPrint.Add "Logs", 3 


    For Each ws In ActiveWorkbook.Worksheets 
    If dontPrint.Exists(ws.Name) Then 
    Else 
     ws.PrintOut 
    End If 
    Next ws 

End Sub