Построение только общих данных в серии данных с GNUPlot

Question

Я пытаюсь создать график, который показывает две строки из двух разных источников данных - которые являются временными рядами. Моя проблема заключается в том, что у одного источника есть данные за каждый день, а у другого - спорадические данные (и начинается позже). Как на следующем рисунке:

Я использую следующий код:

set autoscale xfixmax 
set autoscale xfixmin 
set xdata time 
set timefmt "%s" 
set format x "%m/%y" 
set y2tics 

set terminal png size 1000,500 

set datafile sep ',' 

plot 'a.csv' using 1:2 with line lw 1.2 title 'a' axes x1y1, \ 
'b.csv' using 2:5 with steps lw 2 title 'b' axes x1y2 

Я хотел бы только, чтобы построить период, когда они оба имеют данные. Возможно ли это с GNUPlot?

Спасибо :)

Answer 1

Вы можете использовать команду stats для определения xrange обоих файлов данных. Это не работает в режиме TimeData, но так как у вас есть время, предоставляемое в качестве метки времени вы можете сделать это перед установкой в ​​режиме TimeData:

set datafile sep ',' 

stats 'a.csv' using 1:2 prefix 'a' 
stats 'b.csv' using 2:5 prefix 'b' 

xmin = (a_min_x < b_min_x ? b_min_x : a_min_x) 
xmax = (a_max_x < b_max_x ? a_max_x : b_max_x) 

set xdata time 
set timefmt "%s" 
set format x "%m/%y" 
set y2tics 
set xrange[xmin:xmax] 

set terminal png size 1000,500 

plot 'a.csv' using 1:2 with line lw 1.2 title 'a' axes x1y1, \ 
'b.csv' using 2:5 with steps lw 2 title 'b' axes x1y2