Как я могу автоматизировать существующий экземпляр Internet Explorer с помощью Perl?

Question

Я изо всех сил пытаюсь получить контроль над элементом предварительного просмотра IE, который является классом «Internet Explorer_Server» во внешнем приложении Windows с perl.

Internet Explorer_Server - это имя класса окна, я нашел его со Spy ++. и вот мое утверждение код этого

$className = Win32::GUI::GetClassName($window); 
if ($className eq "Internet Explorer_Server") { 
    ... 
} 

я могу получить дескриптор этого «Интернет Explorer_Server» с Win32::GUI::GetWindow, но понятия не имеют, что делать дальше.

Answer 1

Обновлено: Вы идете по неверному пути. Вам нужно Win32::OLE.

#!/usr/bin/perl 

use strict; 
use warnings; 

use Win32::OLE; 
$Win32::OLE::Warn = 3; 

my $shell = get_shell(); 
my $windows = $shell->Windows; 

my $count = $windows->{Count}; 

for my $item (1 .. $count) { 
    my $window = $windows->Item($item); 
    my $doc = $window->{Document}; 
    next unless $doc; 
    print $doc->{body}->innerHTML; 
} 

sub get_shell { 
    my $shell; 
    eval { 
     $shell = Win32::OLE->GetActiveObject('Shell.Application'); 
    }; 

    die "$@\n" if $@; 

    return $shell if defined $shell; 

    $shell = Win32::OLE->new('Shell.Application') 
     or die "Cannot get Shell.Application: ", 
       Win32::OLE->LastError, "\n"; 
} 
__END__ 

Таким образом, этот код находит окно с Document собственности и печатает HTML. Вам необходимо будет определить, какие критерии вы хотите использовать, чтобы найти интересующее вас окно.

ShellWindows documentation.

Answer 2

Вы смотрели на Samie http://samie.sourceforge.net/, как это Perl модуль для управления IE

Answer 3

Вы можете посмотреть на Win32::IE::Mechanize. Я не уверен, можете ли вы управлять существующим IE-окном с этим модулем, но доступ к одному URL-адресу должен быть возможен примерно в пяти строках кода.