Обновить поле таблицы, заменив подстроки на основе значений из другой таблицы

Question

У меня есть таблица, и я хочу обновить одно из своих полей varchar на основе значений в другой таблице.

У меня есть следующая таблица:

ID Constraint_Value 
---------------------------- 
1 (OldVal_1) (OldVal_2) 
2 (OldVal_2) (OldVal_1) 

... и я хочу использовать данные из следующей таблицы, чтобы сделать обновление:

oldValue newValue 
---------------------------- 
OldVal_1 NewVal_1 
OldVal_2 NewVal_2 

После обновления, я стремлюсь по следующим вопросам:

ID Constraint_Value 
---------------------------- 
1  (NewVal_1) (NewVal_2) 
2  (NewVal_2) (NewVal_1) 

Следующий SQL иллюстрирует мою проблему (которую вы можете запустить в SQL Management Stud ИО без какой-либо настройки):

IF OBJECT_ID('tempdb..#tmpConstraint') IS NOT NULL DROP TABLE #tmpConstraint 
GO 
CREATE TABLE tempdb..#tmpConstraint (constraint_id INT PRIMARY KEY, constraint_value varchar(256)) 
GO 

IF OBJECT_ID('tempdb..#tmpUpdates') IS NOT NULL DROP TABLE #tmpUpdates 
GO 
CREATE TABLE tempdb..#tmpUpdates (oldValue varchar(256), newValue varchar(256)) 
GO 

insert into #tmpConstraint 
values (1, '(OldVal_1) (OldVal_2)') 

insert into #tmpConstraint 
values (2, '(OldVal_2) (OldVal_1)') 

insert into #tmpUpdates 
values ('OldVal_1', 'NewVal_1') 

insert into #tmpUpdates 
values ('OldVal_2', 'NewVal_2') 

select * from #tmpConstraint 

update c 
set constraint_value = REPLACE(constraint_value, u.oldValue, u.newValue) 
from #tmpConstraint c 
cross join #tmpUpdates u 

select * from #tmpConstraint 

Это дает результаты:

(Before) 
1 (OldVal_1) (OldVal_2) 
2 (OldVal_2) (OldVal_1) 

(After) 
1 (NewVal_1) (OldVal_2) 
2 (OldVal_2) (NewVal_1) 

Как вы можете видеть только OldVal_1 был обновлен. OldVal_2 остался прежним.

Как обновить поле со всеми данными в таблице поиска?

Answer 1

UPDATE влияет только на каждую строку источника один раз. Поэтому самый простой обходной путь, о котором я знаю, - это курсор.

DECLARE @o VARCHAR(256), @n VARCHAR(256); 

DECLARE c CURSOR LOCAL STATIC READ_ONLY FORWARD_ONLY 
FOR SELECT oldValue, newValue FROM #tmpUpdates; 

OPEN c; 

FETCH c INTO @o, @n; 

WHILE @@FETCH_STATUS = 0 
BEGIN 
    UPDATE #tmpConstraint 
     -- note full match only: 
     SET constraint_value = REPLACE(constraint_value, '(' + @o + ')', '(' + @n + ')') 
     -- and note we only touch rows where there is a full match: 
     WHERE constraint_value LIKE '%(' + @o + ')%'; 

    FETCH c INTO @o, @n; 
END 

CLOSE c; 
DEALLOCATE c; 

SELECT constraint_id, constraint_value FROM #tmpConstraint; 

Результаты:

constraint_id constraint_value 
------------- --------------------- 
1    (NewVal_1) (NewVal_2) 
2    (NewVal_2) (NewVal_1)