Квалифицировать свойства класса во время/после конструктора (Sub New)

Question

Я ищу способ получить значение свойства во время или после подстроки New(). В общем, хотя я хотел бы знать, есть ли способ вызвать некоторый код автоматически после того, как класс имеет все свойства его свойств полностью инициированы.

В свойствах Sub New() устанавливаются их начальные значения, а не те, которые установлены во время разработки.

По существу, мне интересно, возможно ли установить что-то похожее на событие «Форма показано», за исключением классов.

Код:

Public Class Test 
inherits Component 

Public Event Initiated() 

Public Sub New() 
    MyBase.New() 
    RaiseEvent Initiated() 
End Sub 

Private Sub OnInitiated() Handles Me.Initiated 
    Debug.WriteLine(Max) 
End Sub 

Private _Max As Integer = 5 
Public Property Max() As Integer 
    Get 
     Return _Max 
    End Get 
    Set(ByVal Value As Integer) 
     _Max = Value 
    End Set 
End Property 
End Class 

Примечание: Значение свойства "Max" установлен на 3 с точки зрения дизайна.

Answer 1

Проблема с помощью конструктора, что код дизайнер устанавливает ваш свойства после его создания. Но NET Framework включает интерфейс ISupportInitialize, который идеально подходит для элементов управления и компонентов, которые должны выполнять такие вещи, как, например, квалифицировать свойства, например, проверку ValueпослеMin и Max.

Он прост в использовании:

Imports System.ComponentModel 

Public Class Test 
    Inherits Component 
    Implements ISupportInitialize 

При нажатии клавиши ввода на последней строке, это добавит 2 метода:

Public Sub BeginInit() Implements ISupportInitialize.BeginInit 

Public Sub EndInit() Implements ISupportInitialize.EndInit 

, которая позволяет это сделать:

Public Sub New() 
    MyBase.New() 
End Sub 

Public Sub EndInit() Implements ISupportInitialize.EndInit 
    ' do whatever you want to do 
    ' all properties will be initialized at this time 
    ' e.g. Max will be the IDE value, not 5 
    ... 
End Sub 

Способ, которым это работает, заключается в том, что VS будет ссылаться на это из кода дизайнера после свойств элемента управления/компонента. Если открыть код дизайнера вы увидите что-то вроде этого:

' ctl declarations 
CType(Me.Test1, System.ComponentModel.ISupportInitialize).BeginInit() 

' lots of code initializing controls 
Me.Label1.Name = "Label1" 
... 
Me.Button1.Location = ... 
... 
Me.Test1.Max = 3   ' yours will be there somewhere 

' then at the end: 
CType(Me.Test1, System.ComponentModel.ISupportInitialize).EndInit() 

Таким образом, вы можете добавить любой код, который нужно выполнить, прежде чем что-либо создается в методе BeginInit, и код, который нужно запустить после всех свойства инициализируются в EndInit.

---

BeginInit и EndInit будет работать каждый раз, когда код конструктора запускается. То есть каждый раз во время выполнения и после того, как будет достаточно изменений в форме, которую необходимо перестроить. Вам нужно сохранить код компонента свежим, поскольку VS использует скомпилированную версию его в среде IDE при работе над проектом, используя его.

Итак, перестраивайте часто и очищайте, когда кажется, что он не подбирает изменения.

Answer 2

Единственное, что я мог видеть, чтобы ответить на ваш вопрос, чтобы создать пользовательское событие в своем классе и стрелять в конце конструктора