Sub свойства в модуле класса VBA Excel

Question

У меня есть модуль с именем cTask с ниже кодом в нем:

Private pMile As String 

Public Property Get Mile() As String 
Mile = pMile 
End Property 

Public Property Let Mile(Value As String) 
pMile = Value 
End Property 

Так что в моих подразделах позволяет сказать, что я начинаю

dim currtask as cTask 

Я хотел бы написать

curtask.Mile=TIM 

, а также

curtask.Mile.stat=2 

как

worksook("qqq").sheets("okko").cells(1,1)... 

как мне делать вложенные свойства в моем классе?

EDIT: Так что в одном классе с именем cTask

Private pMile As cMile 
Public Property Get Mile() As String 
Mile = pMile 
End Property 

Public Property Let Mile(Value As String) 
pMile = Value 
End Property 

и в классе cMile я имею

Private pstatus As String 

Public Property Get status() As String 
status = ppstatus 
End Property 

Public Property Let status(Value As String) 
pstatus = Value 
End Property 

тогда в моем суб я все это объявить

dim curtask as cTask 

Это верно? Она не работает, так что я, должно быть, пропустил что-то

Answer 1

Пример реализации вложенных объектов

cTask:

Private pMile As cMile 

Public Property Get Mile() As cMile 
    Set Mile = pMile 
End Property 

Public Property Set Mile(Value As cMile) 
    Set pMile = Value 
End Property 

Private Sub Class_Initialize() 
    Set Me.Mile = New cMile 
End Sub 

---

cMile:

Private pStatus As String 
Private pNumber As Long 

Public Property Get Status() As String 
    Status = pStatus 
End Property 

Public Property Let Status(Value As String) 
    pStatus = Value 
End Property 

Public Property Get Number() As Long 
    Number = pNumber 
End Property 

Public Property Let Number(Value As Long) 
    pNumber = Value 
End Property 

---

Обычный модуль :

Sub Tester() 

    Dim Task As New cTask 

    Task.Mile.Status = "Done" 
    Task.Mile.Number = 11 

    Debug.Print Task.Mile.Status, Task.Mile.Number 

End Sub 

---

Чего не хватает оригинального вопроса заключается в следующем:

curtask.Mile=TIM 

Это не ясно, что вы имели в виду под этим: это вид выглядит как «собственность по умолчанию» на классе cMile, но это не поддерживается в VBA (или, по крайней мере, не легко).