можно отобразить массивСоллекция спрайтов в компоненте List?

Question

У меня есть arrayCollection объектов, которые расширяют Sprite, и имеют растровые изображения внутри них.

Я хочу, чтобы отобразить их в списке

Когда я делаю (или какой-либо другой компонент, который позволит пользователю просматривать их и видеть связанные с ними данные.): MyList.dataProvider = myArrayCollection

список просто показывает кучу строк [Object, Item] вместо визуальных спрайтов.

Вот упрощенная версия моего объекта:

public class myUIC extends UIComponent 
    { 

     public var mySprite:Sprite = new Sprite; 

     [Embed(source="assets/BGimage.png")] 
     public var BGimage:Class; 

     public var myBitmap:Bitmap; 
     public var wordText:TextField = new TextField; 

     public function myUIC(myWord:String) 
     { 
      this.wordText.text = myWord; 
      this.myBitmap = new BGimage; 
      this.mySprite.addChild(this.myBitmap); 
      this.mySprite.addChild(this.wordText); 
      this.addChild(this.mySprite); 
     } 
    } 

Пробовал много разных способов, чтобы получить его, чтобы показать в списке, но не может это сделать.

Answer 1

Похоже, что вы можете попробовать написать простой инструмент визуализации элементов (возможно, на основе UIComponent), который добавляет связанный спрайт в список отображения рендера с помощью addChild().

Answer 2

Смотрите этот учебник: Flex Examples - displaying icons in a flex list control

Answer 3

попробовать rawChildren.addChild для добавления Sprite

Answer 4

Здесь, попробуйте использовать ItemRenderer что-то вроде этого. Он должен работать с любым универсальным DisplayObject. Он захватывает ширину и высоту из назначенного свойства данных, поэтому вам может потребоваться установить variableRowHeight в true в вашем фактическом списке, чтобы он работал, как ожидалось.

package 
{ 
    import flash.display.DisplayObject; 
    import mx.controls.listClasses.IListItemRenderer; 
    import mx.core.UIComponent; 
    import mx.events.FlexEvent; 

    /* 
    Extending UIComponent means we can add Sprites (or any DisplayObject) 
    with addChild() directly, instead of going through the rawChildren property. 
    Plus, in this case, we don't need the extra overhead of Canvas's layout code. 

    IListItemRenderer lets us use it as a List's itemRenderer. UIComponent already 
    implements all of IListItemRenderer except for the data property 
    */ 
    public class SpriteRenderer extends UIComponent implements IListItemRenderer 
    { 
     // Implementing the data property for IListItemRenderer is really easy, 
     // you can find example code in the LiveDocs for IDataRenderer 
     private var _data:Object; 

     [Bindable("dataChange")] 
     public function get data():Object 
     { 
      return _data; 
     } 

     public function set data(value:Object):void 
     { 
      if (value !== _data) { 

       // We need to make sure to remove any previous data object from the child list 
       // since itemRenderers are recycled 
       if (_data is DisplayObject && contains(_data as DisplayObject)) { 
        removeChild(_data as DisplayObject); 
       } 

       _data = value; 

       // Now we just make sure that the new data object is something we can add 
       // and add it 
       if (_data is DisplayObject) { 
        this.width = (_data as DisplayObject).width; 
        this.height = (_data as DisplayObject).height; 

        addChild(_data as DisplayObject); 
       } 

       dispatchEvent(new FlexEvent(FlexEvent.DATA_CHANGE)); 
      } 
     } 

     public function SpriteRenderer() 
     { 
      super(); 
     } 
    } 
}