Компиляция схемы XMLBeans - утилита scomp

Question

У меня есть набор схем, которые не совместимы с JAXB, но совместимы с XMLBeans.

Согласно документации на XMLBeans, я могу использовать scomp для компиляции моей схемы. Но я не могу найти этот инструмент нигде или документацию по его версиям.

Я могу использовать плагин maven для компиляции моей схемы, но это зависит от более старой версии XMLBean (2.4, а не от версии 2.6).

Кто-нибудь знает, какие функции я упускаю из-за ошибок, используя мою схему, скомпилированную с 2.4, а не 2.6, и если я могу использовать скомпилированные классы с зависимостью 2.6 (совместим ли она с обратной связью - ?)

Мой вопрос: где утилита scomp?

Answer 1

Я создал этот BATCH для автоматизации процесса. Надеюсь, поможет!

(в XMLBeans 2.6 нужно просто xbean.jar)

@echo off 
echo *** 
echo * https://xmlbeans.apache.org/docs/2.0.0/guide/tools.html 
echo *** 
setlocal 

SET SOURCE= 
if exist %1.xsd SET SOURCE=%1.xsd 
if exist %1.wsdl SET SOURCE=%1.wsdl 
if not "%SOURCE%"=="" goto JAVA 
echo USAGE: COMP XSD/WSDL FILENAME 
goto END 

:JAVA 
if exist "%JAVA_HOME%\bin\javac.exe" goto XMLBEANS 
echo JAVA SDK NOT FOUND! PLEASE configure JAVA_HOME 
echo %JAVA_HOME% 
goto END 

:XMLBEANS 
SET BEANS_HOME=. 
SET BEANS_SRC=%BEANS_HOME%\src 
SET BEANS_JAR=%BEANS_HOME%\jars 
SET BEANS_LIB=%BEANS_HOME%\lib-2.6 
SET BEANS_CP=%BEANS_LIB%\xbean.jar 
echo JAVA HOME @ %JAVA_HOME% 
echo BEANS HOME @ %BEANS_HOME% 
echo BEANS SRC @ %BEANS_SRC% 
echo BEANS JAR @ %BEANS_JAR% 
echo BEANS LIB @ %BEANS_LIB% 
echo BEANS CP @ %BEANS_CP% 
if exist %BEANS_LIB% goto COMPILE 
echo XMLBEANS LIB NOT FOUND @ %BEANS_LIB% 
goto END 

:COMPILE 
SET JAVA=%JAVA_HOME%\bin\java.exe 
SET JAVAC=%JAVA_HOME%\bin\javac.exe 
echo ***COMPILING*** %SOURCE% 
if not exist %1.xsdconfig goto WITHOUT_CONFIG 

"%JAVA%" -classpath %BEANS_CP% org.apache.xmlbeans.impl.tool.SchemaCompiler -src %BEANS_SRC% -out %BEANS_JAR%\%1.jar %SOURCE% %1.xsdconfig -compiler "%JAVAC%" -javasource "1.5" 
goto END 

:WITHOUT_CONFIG 
echo %1.xsdconfig NOT FOUND! Compiling without xsdconfig 
"%JAVA%" -classpath %BEANS_CP% org.apache.xmlbeans.impl.tool.SchemaCompiler -src %BEANS_SRC% -out %BEANS_JAR%\%1.jar %SOURCE% -compiler "%JAVAC%" -javasource "1.5" 

:END