Как удалить все файлы, но исключая определенные файлы (пакетный файл)

Question

Я знаю, что есть такие вопросы, как это раньше, но в моем случае есть особые условия при указании файлов, которые должны быть исключены в операции «удалить».

примеры Имя файла:

A_001.xml
A_002.xml
B_001.xml
B_002.xml
B_003.xml
C_009.xml
D_002.xml

Файлы выше, находятся в одном каталоге, и мне нужно удалить все файлы, но сохранить одну копию каждого файла с наивысшим счетчиком в имени файла A_002.xm, B_003.xml, C_009.xml и D_002.xml.

Возможно ли это? Я новичок в создании пакетного файла, поэтому, пожалуйста, помогите мне. Я уже знаю, как удалить файлы и даже исключить конкретное расширение файла, но я не знаю, что делать в этом сценарии.

Answer 1

@ECHO OFF 

SETLOCAL enabledelayedexpansion 
:: 
:: establish target directory 
:: initialise PREFIX to a name that's invalid in a filename 
:: 
SET target=. 
SET prefix=: 
FOR /f "tokens=1*delims=_" %%i IN (
'dir /b/a-d/o-n "%target%\*_*.xml' 
) DO (
IF !prefix!==%%i ECHO DEL "%target%\%%i_%%j" 
SET prefix=%%i 
) 

Данное решение основано на наличии «_» в именах * xml-файлов в целевом каталоге. Я испытал это на некоторых фиктивных файлы в моем каталоге пакетной разработки, поэтому я использовал . для the current directory

Команда DIR выдает список файлов в целевом каталоге, которые соответствуют шаблону *_*.xml Переключатель /b означает filename only, /a-d средства no directory names, even if they match и /o-n означает in the reverse order of name Следовательно, имена будут отображаться с наивысшим числовым значением детали после _.

Цикл FOR читает этот вывод и присваивает префикс %%i и оставшуюся часть файла на %%j Так как prefix инициализируется к инвалидному-в-имена файлов характера, он не может соответствовать %%i для первого найденного файла, поэтому DEL не будет выполняться. Затем будет сохранен последний встречный префикс. Только если следующее имя файла имеет соответствующий префикс, будет выполнено DEL

Обратите внимание, что я вставил ключевое слово ECHO перед номером DEL. Это устройство безопасности в случае ошибки. ПРЕДВАРИТЕЛЬНАЯ ПРОГРАММА DEL будет представлена ​​на экране, а не ВЫПОЛНЯЕТСЯ. Как только вы убедитесь, что партия правильная, удалите ECHO, и операция удаления продолжится.

Точка наблюдается:

• Некоторые редакторы довольно бесцеремонно о зачистки или удерживающее задней пространства. Обычно это безопасно, но конечные пробелы в команде SET могут привести к хаосу.

Answer 2

@echo off 
SETLOCAL ENABLEDELAYEDEXPANSION 
set newprefix=_ 
for /F %%a in ('dir /on /b /a-d *.xml') do (
for /F "delims=_" %%i in ("%%a") do (
    IF NOT *%%i*==*!newprefix!* (
    for /F %%q in ('dir /on /b /a-d %%i*.xml') do set lastitem=%%q 
    attrib +r !lastitem! > NUL 
    del /s /q %%i*.xml 1>NUL 2>NUL 
    attrib -r !lastitem! > NUL 
    set newprefix=%%i 
    ) 
) 
) 

Для каждого префикса XML-файл, перечислен все файлы с префиксом в вопросе, чтобы получить последнюю в списке. Затем отметьте последний только для чтения. Удалите все с заданным шаблоном, за исключением чтения. Сбросьте флаг только для чтения и перейдите для следующего префикса.