Пакетный файл. Удалите все файлы и папки в каталоге

Question

Я хочу иметь пакетный файл, который удалит все папки и файлы в моей папке Cache для моего беспроводного инструментария.

В настоящее время я следующее:

cd "C:\Users\tbrollo\j2mewtk\2.5.2\appdb\RMS" 
del *.db 

Это удалит все .DB файлы в моем каталоге RMS, однако я хочу, чтобы удалить каждую вещь из этого каталога

Можете ли вы мне помочь? Благодарю.

Answer 1

del *.* вместо del *.db. Это удалит все.

Answer 2

Попробуйте это, он работает для меня, у меня есть приложение, которое выгружает данные в моей папке «C: \ tmp» & следующее работает лучше всего для меня, оно даже не спрашивает «Да» или «Нет» для удаления данных я сделал график для того, чтобы запустить через каждые 5 минут

cd "C:\tmp" 

del *.* /Q 

Answer 3

IF EXIST "C:\Users\tbrollo\j2mewtk\2.5.2\appdb\RMS" (
    rmdir "C:\Users\tbrollo\j2mewtk\2.5.2\appdb\RMS" /s /q 
) 

Это удалит все из папки (и самой папки).

Answer 4

Создайте пакетный файл

копию ниже текста в пакетный файл

set folder="C:\test" 
cd /d %folder% 
for /F "delims=" %%i in ('dir /b') do (rmdir "%%i" /s/q || del "%%i" /s/q) 

удалит все файлы и папки

Answer 5

еще лучше, скажем, я хочу, чтобы удалить все под C: \ windows \ temp.

@echo off 
rd c:\windows\temp /s /q 

Answer 6

del *.* будет удалять только файлы, но не подкаталоги. Для того, чтобы ядерное оружие содержимого каталога, вы можете использовать этот скрипт:

@echo off 
setlocal enableextensions 
if {%1}=={} goto :HELP 
if {%1}=={/?} goto :HELP 
goto :START 

:HELP 
echo Usage: %~n0 directory-name 
echo. 
echo Empties the contents of the specified directory, 
echo WITHOUT CONFIRMATION. USE EXTREME CAUTION! 
goto :DONE 

:START 
pushd %1 || goto :DONE 
rd /q /s . 2> NUL 
popd 

:DONE 
endlocal 

Answer 7

Вы могли бы использовать Robocopy в зеркале пустой папки в папку, которую вы очищаете.

robocopy "C:\temp\empty" "C:\temp\target" /E /MIR 

Он также работает, если вы не можете удалить или воссоздать фактическую папку.

Для этого требуется существующий пустой каталог.

Answer 8

Просто поместите это вместе с чего morty346 писал:

set folder="C:\test" 
IF EXIST "%folder%" (
    cd /d %folder% 
    for /F "delims=" %%i in ('dir /b') do (rmdir "%%i" /s/q || del "%%i" /s/q) 
) 

Добавляет быструю проверку, что папка определяется в переменной существует, а затем изменяет каталог в папку и удаляет содержимое.

Answer 9

Вы можете сделать это с помощью del/S и флаг (чтобы сказать ему рекурсию все файлы из всех подкаталогов):

del /S C:\Path\to\directory\* 

команда RD может также использоваться.Рекурсивный удалить спокойно без оперативного

@RD /S /Q %VAR_PATH% 

https://technet.microsoft.com/en-gb/library/bb490990.aspx

Answer 10

set "DIR_TO_DELETE=your_path_to_the_folder" 

IF EXIST %DIR_TO_DELETE% (
    FOR /D %%p IN ("%DIR_TO_DELETE%\*.*") DO rmdir "%%p" /S /Q 
    del %DIR_TO_DELETE%\*.* /F /Q 
) 

Answer 11

Просто модифицированная версия https://stackoverflow.com/users/478183/morty346 ответа

set folder="C:\test" 
cd /D %folder% 
if NOT %errorlevel% == 0 (exit /b 1) 
echo entire content of %cd% will be deleted, press Ctrl-C to abort 
pause 
REM first the directories /ad option of dir 
for /F "delims=" %%i in ('dir /b /ad') do (echo rmdir "%%i" /s/q) 
REM now the files /a-d option of dir 
for /F "delims=" %%i in ('dir /b /a-d') do (echo del "%%i" /q) 
REM to deactivate simulation mode remove the word echo before rmdir and del 

Answer 12

@echo off 
@color 0A 

echo Deleting logs 

rmdir /S/Q c:\log\ 

ping 1.1.1.1 -n 5 -w 1000 > nul 

echo adding log folder back 

md c:\log\ 

вы были на правильном пути, просто добавить код, чтобы добавить папка, которая снова удаляется

Answer 13

Использование

set dir="Your Folder Path Here" 
rmdir /s %dir% 
mkdir %dir% 

Эта версия удаляет, не спрашивая:

set dir="Your Folder Here" 
rmdir /s /q %dir% 
mkdir %dir% 

Пример:

set dir="C:\foo1\foo\foo\foo3" 
rmdir /s /q %dir% 
mkdir %dir% 

Это очистит C:\foo1\foo\foo\foo3.

Я хотел бы упомянуть @Abdullah Sabouin с этим ответом https://stackoverflow.com/a/44578851/8238944. Со мной что-то перепуталось. Я не заметил его сообщения.

Я хотел бы поблагодарить @melpomene за указание ошибок!

Answer 14

Вы не можете удалять все с любой rmdir или del только:

• rmdir /s /q не принимает подстановочные Params. Таким образом, ошибка rmdir /s /q *.
• del /s /f /q удалит все файлы, но пустые подкаталоги останутся.

Мой предпочтительным решением (как я использовал во многих других пакетных файлов) является:

rmdir /s /q . 2>NUL 

Answer 15

Вы должны выполнить эту команду, чтобы удалить все файлы дель * *