Строка добавляется только в текстовое поле, когда текстовое поле уже содержит текст

Question

Пользователь вводит текст в txtAddNote, затем нажимает кнопку cmdAddNote, VBA запускает и добавляет примечание к txtNotes с отметкой времени и даты.

Но он работает только тогда, когда уже есть текст в txtNotes. Что мне нужно сделать, чтобы заставить его работать, когда txtNotes пуст?

Private Sub cmdAddNote_Click() 
Dim MyDate As String 

MyDate = Now() 

Form_ClientF.txtNotes = vbCrLf + MyDate + vbCrLf + vbCrLf + Form_ClientF.txtAddNote + vbCrLf + vbCrLf + Form_ClientF.txtNotes 

Form_ClientF.txtAddNote = "" 

End Sub 

Answer 1

Contatenating значение Null и строка может очень хорошо сделать все это Null, так что попробуйте вместо этого:

Form_ClientF.txtNotes = vbCrLf + MyDate + vbCrLf + vbCrLf + Nz(Form_ClientF.txtAddNote, "") + vbCrLf + vbCrLf + Nz(Form_ClientF.txtNotes, "") 

Answer 2

Используйте метод .Value, а не непосредственно со ссылкой на текстовые поля.

В этом случае используйте его всякий раз, когда ссылаетесь на объект Excel VBA - флажки и т. Д. Это сэкономит вам массу разочарований позже с такими проблемами.

Private Sub cmdAddNote_Click() 
Dim MyDate As String 

MyDate = Now() 

Form_ClientF.txtNotes.value = vbCrLf + MyDate + vbCrLf + vbCrLf + Form_ClientF.txtAddNote.value + vbCrLf + vbCrLf + Form_ClientF.txtNotes.value 

Form_ClientF.txtAddNote.value = "" 

End Sub 

Answer 3

Я предполагаю, что вы убедитесь, что вы не участвуете cmdAddNote_Click если txtAddNote не содержит что-то добавить (см пример кода ниже).

Если это так, то вы можете сделать это ...

Form_ClientF.txtNotes = vbCrLf & MyDate & vbCrLf & vbCrLf & _ 
Form_ClientF.txtAddNote & (vbCrLf + vbCrLf + Form_ClientF.txtNotes) 

Этот подход использует разницу между + и &, когда используется для конкатенации строки с Null. Вот пример из окна Immediate, иллюстрирующего разницу.

? "a" + Null 
Null 
? "a" & Null 
a 

Вот захват экрана в форме, которая использует этот подход ...

И код, используемый в форме ...

Option Compare Database 
Option Explicit 

Private Sub cmdAddNote_Click() 
    Me.txtnotes = Format(Now, "mmm dd, yyyy h:nn:ss ampm") & vbCrLf & _ 
     Me.txtAddNote & (vbCrLf + vbCrLf + Me.txtnotes) 
    Me.txtAddNote = vbNullString 
    Me.txtAddNote.SetFocus 
    Me.cmdAddNote.Enabled = False 
End Sub 

Private Sub Form_Current() 
    Me.cmdAddNote.Enabled = (Len(Trim(Nz(Me.txtAddNote, vbNullString))) > 0) 
End Sub 

Private Sub txtAddNote_Change() 
    Me.cmdAddNote.Enabled = (Len(Trim(Nz(Me.txtAddNote.Text, vbNullString))) > 0) 
End Sub