Объединение двух файлов XML с XSLT

Question

Мне нужно объединить два XML-файла с XSLT. Они выглядят так:

<xml xmlns:s='uuid:BDC6E3F0-6DA3-11d1-A2A3-00AA00C14882' 
    xmlns:dt='uuid:C2F41010-65B3-11d1-A29F-00AA00C14882' 
xmlns:rs='urn:schemas-microsoft-com:rowset' 
xmlns:z='#RowsetSchema'> 
<s:Schema id='RowsetSchema'> 
    ... Some stuff 
</s:Schema> 
<rs:data> 
    <z:row Initialer='HBL' personaleGrupper='FF' Fornavn='Harald' Efternavn='Blåtand'  personnummer='123459'/> 
</rs:data> 
</xml> 

И еще один файл с похожим:

<rs:data> 
    <z:row Initialer='KT' personaleGrupper='FF' Fornavn='Kristian' Efternavn='Tyrann' personnummer='546578'/> 
</rs:data> 

Моя попытка была:

<?xml version="1.0" encoding="UTF-8"?> 
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
      xmlns:rs="urn:schemas-microsoft-com:rowset" 
      xmlns:z="#RowsetSchema"> 

<xsl:template match="rs:data"> 
<xsl:copy> 
    <xsl:apply-templates select="@* | node() | document('doc2.xml')/rs:data/z:row/node()" /> 
</xsl:copy> 
</xsl:template> 

<xsl:template match="node() | @*"> 
    <xsl:copy-of select="." /> 
</xsl:template> 

</xsl:stylesheet> 

Однако, я в значительной степени получить копию исходного кода file (doc1.xml). Другими словами, часть схемы есть, и есть одна строка rs: data Харальда Блатанда. Но не линия Кристиана Тирана.

Что я делаю неправильно?

Answer 1

Я не совсем уверен, как выглядит ваш выход.

Следующие xslt будут копировать rs: записи данных из doc2.xml за данными rs: data из первого документа.

<?xml version="1.0" encoding="utf-8"?> 
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
      xmlns:rs="urn:schemas-microsoft-com:rowset" 
      xmlns:z="#RowsetSchema"> 

    <xsl:template match="xml"> 
     <xsl:copy> 
      <xsl:apply-templates select="@* | node() " /> 
      <xsl:apply-templates select="rs:data" mode="copy" /> 
      <xsl:apply-templates select="document('doc2.xml')//rs:data" mode="copy" /> 
     </xsl:copy> 
    </xsl:template> 

    <xsl:template match="rs:data" /> 

    <xsl:template match="*" mode ="copy"> 
     <xsl:copy> 
      <xsl:apply-templates select="@* | node() " /> 
     </xsl:copy> 
    </xsl:template> 

    <xsl:template match="node() | @*"> 
     <xsl:copy> 
      <xsl:apply-templates select="@* | node() " /> 
     </xsl:copy> 
    </xsl:template> 

</xsl:stylesheet> 

И генерирует следующий вывод:

?xml version="1.0"?> 
<xml xmlns:s="uuid:BDC6E3F0-6DA3-11d1-A2A3-00AA00C14882" xmlns:dt="uuid:C2F41010-65B3-11d1-A29F-00AA00C14882" xmlns:rs="urn:schemas-microsoft-com:rowset" xmlns:z="#RowsetSchema"> 
    <s:Schema id="RowsetSchema"> 
     ... Some stuff 
    </s:Schema> 

    <rs:data> 
     <z:row Initialer="HBL" personaleGrupper="FF" Fornavn="Harald" Efternavn="Bl&#xE5;tand" personnummer="123459"/> 
    </rs:data> 
    <rs:data> 
     <z:row Initialer="KT" personaleGrupper="FF" Fornavn="Kristian" Efternavn="Tyrann" personnummer="546578"/> 
    </rs:data> 
</xml> 

Обновление: Кажется, что должен быть только один RS: данные в выходе и только объединить Z: строки. Попробуйте это:

<?xml version="1.0" encoding="utf-8"?> 
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
      xmlns:rs="urn:schemas-microsoft-com:rowset" 
      xmlns:z="#RowsetSchema"> 

    <xsl:template match="xml"> 
     <xsl:copy> 
      <xsl:apply-templates select="@* | node() " /> 
     </xsl:copy> 
    </xsl:template> 

    <xsl:template match="rs:data" > 
     <xsl:copy> 
      <xsl:apply-templates select="@* | node() " /> 
      <xsl:apply-templates select="document('doc2.xml')//rs:data/*" /> 
     </xsl:copy> 
    </xsl:template> 

    <xsl:template match="node() | @*"> 
     <xsl:copy> 
      <xsl:apply-templates select="@* | node() " /> 
     </xsl:copy> 
    </xsl:template> 
</xsl:stylesheet> 

, который генерирует:

<xml xmlns:s="uuid:BDC6E3F0-6DA3-11d1-A2A3-00AA00C14882" xmlns:dt="uuid:C2F41010-65B3-11d1-A29F-00AA00C14882" xmlns:rs="urn:schemas-microsoft-com:rowset" xmlns:z="#RowsetSchema"> 
    <s:Schema id="RowsetSchema"> 
     ... Some stuff 
    </s:Schema> 
    <rs:data> 
     <z:row Initialer="HBL" personaleGrupper="FF" Fornavn="Harald" Efternavn="Bl&#xE5;tand" personnummer="123459"/> 
     <z:row Initialer="KT" personaleGrupper="FF" Fornavn="Kristian" Efternavn="Tyrann" personnummer="546578"/> 
    </rs:data> 
</xml>