Perl поддержка юникода из консоли (@ARGV)/Windows/

Question

Я пытаюсь получить Юникода в качестве аргументов в PERL скрипт:

C:\>perl test.pl ö 

#---- 
# test.pl 
#---- 
#!/usr/bin/perl 
use warnings; 
use strict; 

my ($name, $number) = @ARGV; 

if (not defined $name) { 
    die "Need name\n"; 
} 

if (defined $number) { 
    print "Save '$name' and '$number'\n"; 
    # save name/number in database 
    exit; 
} 

if ($name eq 'ö') { 
    print "Fetch umlaut 'oe'\n"; 
} elsif ($name eq 'o') { 
    print "Fetch simple 'o'\n"; 
} else { 
    print "Fetch other '$name'\n"; 
} 

print "ü"; 

и я получаю результат:

Fetch simple 'o' 
ü 

I 'протестировал код (алгоритм) в python 3, и он работает, поэтому я получаю «ö». Но, очевидно, в perl есть что-то большее, что я должен добавить или установить. Не имеет значения, это Strawberry Perl или ActiveState Perl. Я получаю тот же результат.

Заранее благодарен!

Answer 1

#!/usr/bin/perl 

use strict; 
use warnings; 

my $encoding_in; 
my $encoding_out; 
my $encoding_sys; 
BEGIN { 
    require Win32; 

    $encoding_in = 'cp' . Win32::GetConsoleCP(); 
    $encoding_out = 'cp' . Win32::GetConsoleOutputCP(); 
    $encoding_sys = 'cp' . Win32::GetACP(); 

    binmode(STDIN, ":encoding($encoding_in)"); 
    binmode(STDOUT, ":encoding($encoding_out)"); 
    binmode(STDERR, ":encoding($encoding_out)"); 
} 

use Encode qw(decode); 

{ 
    my ($name, $number) = map { decode($encoding_sys, $_) } @ARGV; 

    if (not defined $name) { 
     die "Need name\n"; 
    } 

    if (defined $number) { 
     print "Save '$name' and '$number'\n"; 
     # save name/number in database 
     exit; 
    } 

    if ($name eq 'ö') { 
     print "Fetch umlaut 'oe'\n"; 
    } elsif ($name eq 'o') { 
     print "Fetch simple 'o'\n"; 
    } else { 
     print "Fetch other '$name'\n"; 
    } 

    print "ü"; 
} 

Кроме того, вы должны добавить use feature qw(unicode_strings); и/или кодировать файл, используя UTF-8 и добавить use utf8;.

Answer 2

В дополнение к тонкому ответу ikagami, я являюсь поклонником модуля Encode::Locale, который автоматически создает псевдонимы для кодовых страниц текущей консоли. Он отлично работает с Win32, OS X & другими вкусами * nix.

#!/usr/bin/perl 

use strict; 
use warnings; 

# These two lines make life better when you leave the world of ASCII 
# Just remember to *save* the file as UTF8.... 
use utf8; 
use feature 'unicode_strings'; 

use Encode::Locale 'decode_argv';   # We'll use the console_in & console_out aliases as well as decode_argv(). 
use Encode; 

binmode(STDIN, ":encoding(console_in)"); 
binmode(STDOUT, ":encoding(console_out)"); 
binmode(STDERR, ":encoding(console_out)"); 

decode_argv(); # Decode ARGV in place 
my ($name, $number) = @ARGV; 

if (not defined $name) { 
    die "Need name\n"; 
} 

if (defined $number) { 
    print "Save '$name' and '$number'\n"; 
    # save name/number in database 
    exit; 
} 

if ($name eq 'ö') { 
    print "Fetch umlaut 'oe'\n"; 
} elsif ($name eq 'o') { 
    print "Fetch simple 'o'\n"; 
} else { 
    print "Fetch other '$name'\n"; 
} 

print "ü"; 

Возможно, это только синтаксический сахар, но он облегчает чтение и способствует кросс-платформенной совместимости.