Я использую класс Manager I, созданный для управления связкой объектов, которые могут быть назначены любому типу «списка» на основе String. т.е. вы можете назначить его «врагам» и «ALL_OBJECTS». Класс использует pop() для почти мгновенного удаления (и использует объект, а не индекс, который нужно удалить, как вы хотели).
Вот объект, который вы создали бы и ссылку на менеджер:
public class AvGlyph extends Object
{
// vars
internal var signatures:Array = [];
private var _attachment:Object;
/**
* Constructor
* @param attachTo An Object to set as the attachment for this
*/
public function AvGlyph(attachTo:Object)
{
_attachment = attachTo;
}
/**
* Dissolves this, destroying reference to _attachment and fully detaching itself
*/
public function dissolve():void
{
_attachment = null;
AvGlyphManager.fullyDetach(this);
}
/**
* Basic getters
*/
public function get attachment():Object{ return _attachment; }
/**
* Returns an Array containing all signatures applied to this
*/
public function get allSignatures():Array
{
var a:Array = [];
var i:String;
for(i in signatures) a.push(i);
return a;
}
}
И это менеджер для них:
public class AvGlyphManager
{
// properties
private static var _glyphs:Array = [];
/**
* Attaches an AvGlyph to a specified list
* @param glyph The AvGlyph to attach
* @param signatures Signature Strings used to represent categories
*/
public static function attach(glyph:AvGlyph, ...signatures):void
{
var i:String;
for each(i in signatures)
{
if(!_glyphs[i]) _glyphs[i] = [];
if(!glyph.signatures[i])
{
glyph.signatures[i] = _glyphs[i].length;
_glyphs[i].push(glyph);
}
}
}
/**
* Detach an AvGlyph from a specified list
* @param glyph The AvGlyph to detach
* @param signature Signature Strings used to represent categories
*/
public static function detach(glyph:AvGlyph, ...signatures):void
{
var i:String;
for each(i in signatures)
{
var n:uint = glyph.signatures[i];
if(n == _glyphs[i].length - 1) _glyphs[i].pop();
else
{
_glyphs[i][n] = _glyphs[i].pop();
_glyphs[i][n].signatures[i] = n;
}
if(_glyphs[i].length < 1) delete _glyphs[i];
}
}
/**
* Detach an AvGlyph from all previously specified listings
* @param glyph The AvGlyph to detach
*/
public static function fullyDetach(glyph:AvGlyph):void
{
var i:String;
for(i in glyph.signatures) detach(glyph, i);
}
/**
* Returns a Array of all AvGlyphs that have been attached with a specified signature
* @param signature A signature String used to represent a category
*/
public static function getGlyphs(signature:String):Array
{
if(!_glyphs[signature])return [];
return _glyphs[signature].slice();
}
/**
* Trace a tree of signatures and their children
*/
public static function traceTree():void
{
trace('a');
}
}
Использования просто:
В ваш класс, скажем, Zombie.as, вы могли бы иметь.
public class Zombie extends Sprite
{
private var _glyph:AvGlyph;
/**
* Constructor
*/
public function Zombie()
{
_glyph = new AvGlyph(this);
AvGlyphManager.attach(_glyph, "enemies");
}
}
Отсюда, вы можете в любом месте в использовании приложение/игра:
AvGlyphManager.getGlyphs("enemies");
который вернет массив глифов, перечисленных в разделе «врагов». Для доступа к самому Зомби выполняется просто с помощью glyph.attachment. Так, в цикле через все ваши объекты было бы что-то вдоль линий:
var li:Array = AvGlyphManager.getGlyphs("enemies");
var i:AvGlyph;
for each(i in li)
{
trace(i.attachment);
}
удаления, вероятно просто, если вы берете быстрый взгляд через AvGlyphManager, а также.Есть также:
AvGlyphManager.fullyDetach(glyph);
Это очень полезно, когда вы хотите полностью удалить объект.