Perl split by regexp issue

Question

Я пишу парсер на Perl, и вот проблема с split. Вот мой код:

my $str = 'a,b,"c,d",e'; 
my @arr = split(/,(?=([^\"]*\"[^\"]*\")*[^\"]*$)/, $str); 
# try to split the string by comma delimiter, but only if comma is followed by the even or zero number of quotes 

foreach my $val (@arr) { 
    print "$val\n" 
} 

Я ожидал следующее:

a 
b 
"c,d" 
e 

Но это то, что я действительно получил:

a 
b,"c,d" 
b 
"c,d" 
"c,d" 

e 

Я вижу, мои части строк в массиве , их индексы равны 0, 2, 4, 6. Но как избежать этих нечетных b,"c,d" и других частей строки ожидания в результирующем массиве? Есть ли какая-либо ошибка в моем разделителе регулярных выражений или есть некоторые специальные параметры split?

Answer 1

Вы должны использовать не-захвата группы:

my @arr = split(/,(?=(?:[^\"]*\"[^\"]*\")*[^\"]*$)/, $str); 
         ^^ 

См IDEONE demo

В противном случае, захваченные тексты выводятся как часть результирующего массива.

См perldoc reference:

Если регулярное выражение имеет группировки, то список выпускаемого совпавшие подстроки из группировок, а

Answer 2

ли соответствие вместо расщепления.

use strict; use warnings; 

my $str = 'a,b,"c,d",e'; 
my @matches = $str =~ /"[^"]*"|[^,]+/g; 
foreach my $val (@matches) { 
    print "$val\n" 
} 

Answer 3

Что расцепления вас особенность в split в том, что если вы используете группу, и он установлен, чтобы захватить - он возвращает захваченный «немного» а.

Но вместо того, чтобы использовать split я хотел бы предложить модуль Text::CSV, который уже обрабатывает квотирование для вас:

#!/usr/bin/env perl 
use strict; 
use warnings; 
use Text::CSV; 

my $csv = Text::CSV->new(); 
my $fields = $csv->getline(\*DATA); 

print join "\n", @$fields; 

__DATA__ 
a,b,"c,d",e 

распечаток:

a 
b 
c,d 
e 

Мои рассуждения довольно просто - вы делаете цитаты совпадение и может иметь такие вещи, как цитаты/экранированные цитаты и т. д., означает, что вы делаете рекурсивный синтаксический анализ, что-то regex, просто не подходит для выполнения.

Answer 4

Вы можете использовать parse_line() из Text::ParseWords, если вы на самом деле не ограничены для регулярных выражений:

use Text::ParseWords; 

my $str = 'a,b,"c,d",e'; 

my @arr = parse_line(',', 1, $str); 

foreach (@arr) 
{ 
    print "$_\n"; 
} 

Выход:

a 
b 
"c,d" 
e