В SQL как получить родительское значение по значению столбца

Question

Я работаю над SQL Server 2005 и самым низким.

У меня есть структура таблицы SQL Server, как показано ниже:

ID Name  ParentID 
----------------------- 
1  Root  NULL 
2  Business 1 
3  Finance 1 
4  Stock  3 

Я хочу написать запрос, когда пользователь даст ввод ID = 1, то показать этот вывод здесь:

ID Name  ParentName 
------------------------- 
1  Root  - 
2  Business Root 
3  Finance Root 
4  Stock  Finance  

если пользователь дает ввод ID = 3, то показать этот вывод здесь:

ID Name  ParentName 
------------------------- 
3  Finance Root 
1  Root  - 
4  Stock  Finance 

Когда пользователь даст ввод ID = 4, затем показать этот вывод:

ID Name  ParentName 
------------------------- 
4  Stock  Finance  
3  Finance Root 
1  Root  - 

Заранее благодарен. Если есть запрос plz ask. спасибо за все

Answer 1

SELECT t1.ID, t1.Name, t2.Name AS ParentName FROM tableName t1 
LEFT JOIN tableName t2 on t1.ID = t2.ParentID 

Заменить tableName, очевидно, с таблицей. Добавить t2.ID, чтобы выбрать список, чтобы посмотреть матч, если хотите.

Answer 2

Эти два рекурсивных выражения CTE (Common Table Expression) выберет иерархию из заданного узла вниз в вашем дереве, а также от этого узла до дерева обратно к корню. Так как это CTE, он будет работать в SQL Server 2005 и новее - но не является в SQL Server 2000, к сожалению.

DECLARE @StartID INT 
SET @StartID = 1 

;WITH DownHierarchy AS 
(
    SELECT ID, Name, ParentID 
    FROM dbo.YourTable 
    WHERE ID = @StartID 

    UNION ALL 

    SELECT d.ID, d.Name, d.ParentID 
    FROM dbo.YourTable d 
    INNER JOIN DownHierarchy h ON d.ParentID = h.ID 
), 
UpHierarchy AS 
(
    SELECT ID, Name, ParentID 
    FROM dbo.YourTable 
    WHERE ID = @StartID 

    UNION ALL 

    SELECT d.ID, d.Name, d.ParentID 
    FROM dbo.YourTable d 
    INNER JOIN UpHierarchy h ON d.ID = h.ParentID 
) 
SELECT * 
FROM DownHierarchy 
UNION 
SELECT * 
FROM UpHierarchy 

Установка @StartID = 1 даст вам этот вывод:

ID Name ParentID 
1 Root  NULL 
2 Business 1 
3 Finance 1 
4 Stock  3 

Установка @StartID = 3 даст вам этот вывод:

ID Name  ParentID 
1 Root  NULL 
3 Finance 1 
4 Stock  3 

Answer 3

Вот модификация ответа marc_s':

Declare @data table 
(ID bigint identity(1,1) ,Name varchar(100), ParentID bigint) 

Insert into @data SELECT 'Root',NULL 
Insert into @data SELECT 'Business',1 
Insert into @data SELECT 'Finance',1 
Insert into @data SELECT 'Stock',3 


DECLARE @StartID INT 
SET @StartID = 3 

;WITH DownHierarchy AS 
(
    SELECT ID, Name, ParentID 
    FROM @data 
    WHERE ID = @StartID 

    UNION ALL 

    SELECT d.ID, d.Name, d.ParentID 
    FROM @data d 
    INNER JOIN DownHierarchy h ON d.ParentID = h.ID 
), 
UpHierarchy AS 
(
    SELECT ID, Name, ParentID 
    FROM @data 
    WHERE ID = @StartID 

    UNION ALL 

    SELECT d.ID, d.Name, d.ParentID 
    FROM @data d 
    INNER JOIN UpHierarchy h ON d.ID = h.ParentID 
) 
SELECT * 
FROM DownHierarchy 
UNION 
SELECT * 
FROM UpHierarchy 

Answer 4

У меня есть подобный ответ - но построив его, я хочу, чтобы разместить его;)

declare @Data table (
    ID int not null, 
    Name varchar(50) not null, 
    ParentID int null 
); 

insert into @Data 
select 1, 'Root', null 
union select 2, 'Business', 1 
union select 3, 'Finance', 1 
union select 4, 'Stock', 3; 

declare @UserInput int; 
set @UserInput = 4; 

with cParents as (
    select d.ID, d.Name, d.ParentID 
    from @Data d 
    where d.ID = @UserInput 
    union all 
    select d.ID, d.Name, d.ParentID 
    from cParents c 
    inner join @Data d 
     on d.ID = c.ParentID 
), 
cChildren as (
    select d.ID, d.Name, d.ParentID 
    from @Data d 
    where d.ID = @UserInput 
    union all 
    select d.ID, d.Name, d.ParentID 
    from cChildren c 
    inner join @Data d 
     on d.ParentID = c.ID 
) 
select RecordType='self', d.ID, d.Name, ParentName=isnull(p.Name,'') 
from @Data d 
left join @Data p 
    on p.ID = d.ParentID 
where d.ID = @UserInput 

union all 

select RecordType='parents', d.ID, d.Name, ParentName=isnull(p.Name,'') 
from cParents d 
left join @Data p 
    on p.ID = d.ParentID 
where d.ID <> @UserInput 

union all 

select RecordType='children', d.ID, d.Name, ParentName=isnull(p.Name,'') 
from cChildren d 
left join @Data p 
    on p.ID = d.ParentID 
where d.ID <> @UserInput; 

@data представляют выборочные данные, @UserInput является входным переменным. Я добавил RecordType, чтобы прояснить смысл частей записи. Он протестирован на SQL Server 2008 и должен работать в 2005 году, но не в 2000 году.