гистограмма без вертикальных линий в Mathematica

Question

Я пытаюсь сделать гистограмму без вертикальных линий. Я хотел бы иметь сюжет, который выглядит как функция. Например:

Тот же вопрос был задан для R до (histogram without vertical lines), но я нахожусь в Mathematica.

Я искал варианты ChartStyle без успеха.

Answer 1

Возможно, есть способы сделать это, возившись с EdgeForm[] и FaceForm[] в Histogram, но я нашел проще прокрутить один самостоятельно, когда мне это нужно. Вот очень простой и быстрый пример:

histPlot[data_, bins_, color_: Blue] := Module[{ 
     countBorder = 
    Partition[Riffle[Riffle[#1, #1[[2 ;;]]], Riffle[#2, #2]], 2] & @@ 
    HistogramList[data, bins, "PDF"] 
    }, 
    ListLinePlot[countBorder, PlotStyle -> color] 
    ] 

Ведение histPlot[RandomReal[NormalDistribution[],{1000}],{-3,3,0.1}] дает

Вы можете расширить это принять любой вариант вместо просто "PDF", и за исключением случаев, когда вы хотите автоматически выбирайте бункеры. Мне не нравится автоматическое бининг, потому что мне нравится контролировать ширину и экстенсивность моего бункера для предсказуемости и простого сравнения с другими графиками.

Answer 2

Вы можете также использовать ListPlot с InterpolationOrder->0:

(* example data *) 
data = RandomVariate[NormalDistribution[], 10^3]; 

hist = HistogramList[data, {.5}]; 

ListPlot[Transpose[{hist[[1]], ArrayPad[hist[[2]], {0, 1}, "Fixed"]}], 
    InterpolationOrder -> 0, 
    Joined -> True, 
    AxesOrigin -> {hist[[1, 1]], 0}] 

Answer 3

Вот два способа, которые работают в 7-ой версии, используя постобработку:

rdat = RandomReal[NormalDistribution[0, 1], 200];

MapAt[ 
    {Blue, 
    Line[# /. {{Rectangle[{x_, y_}, {X_, Y_}]}} :> Sequence[{x, Y}, {X, Y}]] } &, 
    Histogram[rdat, PerformanceGoal -> "Speed"], 
    {1, 2, 2, 2} 
] 

Cases[ 
    Histogram[rdat, PerformanceGoal -> "Speed"], 
    Rectangle[{x_, y_}, {X_, Y_}] :> {{x, Y}, {X, Y}}, 
    \[Infinity] 
]; 

Graphics[Line[Join @@ %], AspectRatio -> 1/GoldenRatio, Axes -> True]