Регулярного выражения в Perl

Question

У меня есть задание, которое «найти количество строк, который содержит по крайней мере 3 нулей и не более 2 1сок» и мой алфавит содержит только 0 и 1. я пытался писать так:

(if $line =~ /0{3,}/) 

но это дало мне всего лишь 3 "последовательных" нули.

Чем я попытался это:

(if $line =~ /0+0+0+/) 

снова он дал мне последовательные нули.

Какова логика проверки всей строки и найти количество всех нулей в этой строке независимо от того, являются ли они последовательными или нет.

Answer 1

#match a 0 + anything + 0 + anything + 0, and not (!) 1...1...1 
if (($line =~ /0.*0.*0/) && !($line =~ /1.*1.*1/)) { 
    $count++; 
} 

Answer 2

Этот положительный предпросмотр на основе регулярных выражений должно работать:

/^(?=(?:1*0){3})(?=0*(?:10*){0,2}\z)/ 

Answer 3

Если она содержит по крайней мере три нуля, она содержит нуль, а затем ноль или более символов, заканчивающуюся нулем, а затем ноль или более символов, за которым следует ноль.

$line =~ /0.*0.*0/s 
    -or- 
$line =~ /^[^0]*0[^0]*0[^0]*0/ # More efficient for strings that don't match. 
    -or- 
$line =~ /^(?:[^0]*0){3}/  # Avoid code repetition 

Если он содержит не более двух единиц, он не содержит по меньшей мере трех.

$line !~ /^(?:[^1]*1){3}/ 

Так,

$line =~ /^(?:[^0]*0){3}/ && $line !~ /^(?:[^1]*1){3}/ 

Answer 4

Я бы рассчитывать замену, после того, как все они своего рода часть регулярного выражения, не так ли?

В скалярном контексте s{0}{0}g будет возвращать количество раз, когда была выполнена замена, которая представляет собой число 0 в строке. Таким образом, s{0}{0}g >= 3 && s{1}{1}g <=2 будет условием, которое вы ищете.

Вот небольшая тестовая программа, чтобы проверить это:

#!/usr/bin/perl 

use strict; 
use warnings; 

use Test::More; 

while(<DATA>) 
    { chomp; 
    my($nb, $expected)= split /\s*=>\s*/; 
    # the for topicalizes $nb so we don't have to write it in the condition 
    for ($nb) 
     { my $got= s{0}{0}g >= 3 && s{1}{1}g <=2 ? 'ok' : 'nok'; 
     is($got, $expected, "testing $nb ($expected)"); 
     } 
    } 

done_testing(); 

__DATA__ 
00011 => ok 
01010 => ok 
1000 => ok 
000 => ok 
0000 => ok 
1100000=> ok 
0  => nok 
00  => nok 
1  => nok 
11  => nok 
111 => nok 
10  => nok 
100 => nok 
1100 => nok 
111000 => nok 
010101 => nok