Gnuplot скрипт создает изображение с черным фоном вместо ожидаемой картины

Question

Это часть сценария GNUPLOT я использую:

set terminal png transparent 
#plot "back.png" binary filetype=png w rgbimage 
filename = "/MyData/MyRadio/ND/Server/GNUPlot/anim/map_".i.".dat" 
plotfile = "/MyData/MyRadio/ND/Server/GNUPlot/anim/graph_".i.".png" 
set output plotfile 
set ylabel "Latitude" 
set xlabel "Longitude" 
set cbrange [0.5e9:3e9] 
set palette defined (0.5 "blue", 1 "green",1.5 "yellow", 2.1 "orange", 3 "red") 
plot 'back.png' binary filetype=png center=(0,0) with rgbimage notitle, \ 
filename using 2:3:4 title columnheader(1) with points pt 7 ps 2 palette 
set output 
i=i+1 
if (i <= n) reread 

Однако производит .png файл с черным фоном вместо картины:

.

Answer 1

В случае важных переговоров, если вам нужно создать анимированные .gif как это out.gif ти постоянного изображения на фоне, Вы можете использовать этот code.plt:

reset 
set term png transparent truecolor size 930, 880 
set output "outpit".i.".png" 
set multiplot 
set origin 0,0 
filename = "in_".i.".dat" 
print filename." ".plotfile 
unset tics 
unset border 
set lmargin at screen 0.08 
set rmargin at screen 0.85 
set bmargin at screen 0.1 
set tmargin at screen 0.98 
plot "background.png" binary filetype=png center=(0,0) with rgbimage 
set tics 
set border 
set xrange [40.1:63.11] 
set yrange [49.28:62.44] 
set cbrange [0.5e9:3e9] 
set palette defined (0.5 "blue", 1 "green",1.5 "yellow", 2.1 "orange", 3 "red") 
plot filename using 2:3:4 title columnheader(1) with points pt 7 ps 3 palette 
unset multiplot 
unset output 
i=i+1 
if (i <= n) reread 

Не забудьте установить i (начало) и n (остановка). После того, как все собралось .png в анимированном .gif image whith ffmpg например.

Answer 2

Проблема в цветовой гамме, которая идет [0.5e9:3e9]. и RGBimage до 256 (как вы можете видеть в ссылке, опубликованной в приведенном выше комментарии).

попробовать что-то вроде:

c_min=0.5e9 
c_max=3e9 

set cbrange [c_min:c_max] 
plot \ 
'test.png' binary filetype=png center=(0,0) u 1:2:(c_min+$3/256.*(c_max-c_min)) with rgbimage notitle, \ 
'test.txt' with points pt 7 ps 2 palette 

Это может быть ошибка в Gnuplot, потому что rgbimages не должны быть затронуты Colorbar (так как они используют правильную Colorbar).

в противном случае я бы предложил использовать Multiplot, как это сделано HERE