Excel Macro в VBA - Как применить цикл для перемещения столбцов

Question

У меня есть вспомогательный макрос, который в основном работает как конвертер валют, который позволяет пользователю определять свои собственные значения обменного курса. Я тестировал его на одной ячейке и отлично работал, но мне нужно, чтобы он зацикливался и перемещался по строке для диапазона определения. (В настоящее время клетки, определенные в L2, K2 и G», нужно не повторить на L3, K3 и G3 до Ln, Кп и Gn и т.д.)

код выглядит следующим образом:

Sub Macro9() 
' 
' Macro9 Macro 
' 

Dim score As String, result As String 
score = Sheets("Paste Orders Here").Range("K2").Value 

If score = "USD" Then 
    result = Sheets("Paste Orders Here").Range("L2") * Sheets("Configuration").Range("C5") 
ElseIf score = "EUR" Then 
    result = Sheets("Paste Orders Here").Range("L2") * Sheets("Configuration").Range("B5") 
ElseIf score = "GBP" Then 
    result = Sheets("Paste Orders Here").Range("L2") 
ElseIf score = "" Then 
    result = Sheets("Paste Orders Here").Range("K2") 
End If 

Sheets("Brightpearl").Range("G2").Value = result 
' 
End Sub 

Спасибо, Я понимаю, что это может быть совершенно неверно, если вы хотите применить это к нескольким строкам, но я действительно мог бы вам помочь!

Answer 1

Вот моя интерпретация. Я не был уверен, как далеко заполнить формулы, поскольку вы только ссылались на это как n, поэтому я использовал нижнюю часть Вставить здесь ' s колонка L.

Sub Macro9() 
    Dim r As Long, lr As Long 
    With Sheets("Paste Orders Here") 
     lr = .Cells(.Rows.Count, "K").End(xlUp).Row 
     For r = 2 To lr 
      Select Case UCase(.Cells(r, "K").Value) 
       Case "USD" 
        Sheets("Brightpearl").Cells(r, "G") = _ 
         CCur(.Cells(r, "L").Value * Sheets("Configuration").Range("C5").Value) 
       Case "EUR" 
        Sheets("Brightpearl").Cells(r, "G") = _ 
         CCur(.Cells(r, "L").Value * Sheets("Configuration").Range("B5").Value) 
       Case "GBP" 
        Sheets("Brightpearl").Cells(r, "G") = CCur(.Cells(r, "L").Value) 
       Case Else 
        Sheets("Brightpearl").Cells(r, "G") = .Cells(r, "K").Value 
      End Select 
     Next r 
    End With 
End Sub 

я нахожу метод Select Case работает хорошо в этих случаях и обеспечивает легкость расширения в будущем.