VBA macro crashing Excel

Question

Привет, товарищи,

Я запускаю макрос, чтобы удалить целые строки, содержащие определенное значение. Код работает отлично на небольших наборах данных, но на текущем (~ 22 000 записей) он последовательно сбой Excel (2010). Код ниже. Если вы не разделите данные на более мелкие куски и снова запустите макрос, я не уверен, что делать.

Любая помощь приветствуется и вот код:

Sub CleanOcc() 

'Row counting 
Dim Firstrow As Long 
Dim Lastrow As Long 
Dim Lrow As Long 
Dim Lrow2 As Long 

With Sheets("Occ_Prep") 

    'Cleans the occ_prep sheet ready for upload (Column and value can be changed) 
    Sheets("Occ_Prep").Activate 

    'Set the first and last row to loop through 
    Firstrow = .UsedRange.Cells(1).Row 
    Lastrow = .UsedRange.Rows(.UsedRange.Rows.Count).Row 

    'We loop from Lastrow to Firstrow (bottom to top) 
    For Lrow2 = Lastrow To Firstrow Step -1 

     'We check the values in the A column in this example 
     With .Cells(Lrow2, "K") 


      If Not IsError(.Value) Then 

       If .Value = "0" Then .EntireRow.Delete 
       'This will delete each row with the Value "ron" 
       'in Column A, case sensitive. 

      End If 

     End With 

    Next Lrow2 

End With 



End Sub 

Answer 1

Согласен с Сиддхарт комментарий автофильтр путь. Это должно быть намного быстрее.

Option Explicit 
Sub delrows() 
    Dim ws As Worksheet 
    Dim LR As Long 
    Dim rng As Range, frng As Range 

    Application.ScreenUpdating = False 

    Set ws = Sheets("dataset") '<-- Change this to name of your worksheet 
    With ws 
     LR = .Range("A" & Rows.Count).End(xlUp).Row 
     .AutoFilterMode = False 
     Set rng = .Range("A1:C" & LR) '<-- Assuming K is the last column 
     rng.AutoFilter 3, "0" '<-- 11 referes to Column K 
     Set frng = rng.Offset(1, 0).SpecialCells(xlCellTypeVisible) '<-- Don't delete the header 
     frng.EntireRow.Delete 
     .AutoFilterMode = False 
    End With 

    Application.ScreenUpdating = True 
End Sub 

Редактировать: Я только что очистил ~ 20000 строк (3 столбца) данных за ~ 5 секунд. Очевидно, это зависит от количества матчей.