Свойство объекта сеанса Grails не устанавливается во время теста интеграции

Question

Я пытаюсь протестировать фильтр в Grails 2.2.1, который хранит значение в глобальном объекте session в любое время, когда кто-то удаляет любой URL-адрес моего приложения. Вот что я придумал, благодаря this fine post:

package drummer 

class SessionExpirationFilters { 

    def filters = { 
     all(controller: '*', action: '*') { 
      before = { 
       session.foo = 'bar' 
      } 
     } 
    } 
} 

Я могу видеть, что фильтр работает путем вывода session.foo в методе контроллера, но тест интеграции не удается:

package drummer 

import grails.plugin.spock.IntegrationSpec 

class QuestionControllerIntegrationSpec extends IntegrationSpec { 

    def 'filter sets session foo to bar'() { 
     given: 
     def controller = new QuestionController() 

     when: 
     controller.list() 

     then: 
     assert 'bar' == controller.session.foo // fails, session.foo is null 
    } 
} 

Так почему не задано свойство объекта «foo» session в тесте интеграции?

Answer 1

Причина, по которой он не вызывается, заключается в том, что фильтры НЕ запускаются автоматически в тестах контроллера. Если ваш фильтр находится в сервисе/утилите, вы можете написать для этого отдельные тесты.

Люк Daley писал в блоге о создании интеграционных тестов для filters здесь, если вы хотите, чтобы проверить свои фильтры непосредственно:

import grails.util.GrailsWebUtil 

class MyFilterTests extends GroovyTestCase { 
    def filterInterceptor 
    def grailsApplication 
    def grailsWebRequest 

    def request(Map params, controllerName, actionName) { 
     grailsWebRequest = GrailsWebUtil.bindMockWebRequest(grailsApplication.mainContext) 
     grailsWebRequest.params.putAll(params) 
     grailsWebRequest.controllerName = controllerName 
     grailsWebRequest.actionName = actionName 
     filterInterceptor.preHandle(grailsWebRequest.request, grailsWebRequest.response, null) 
    } 

    def getResponse() { 
     grailsWebRequest.currentResponse 
    } 

    def testFilterRedirects() { 
     def result = request("home", "index", someParameter: "2") 
     assertFalse result 
     assertTrue response.redirectedUrl.endsWith(/* something */) 
    }  
}