Отменить установку, если зависимость не установлена ​​

Question

У меня есть один файл .msi и два файла предварительных условий. В соответствии с моим кодом установка будет выполнять основной файл exe из файла .msi после успешной установки. Но если предыдущая версия .msi-файла уже установлена, она поставляется с опцией Repair and Remove. Мой раздел Run работает после того, как я удалил .msi-файл, и я хочу выйти из приложения после удаления файла msi или не выполнить раздел Run. Может кто-нибудь предложить мне некоторые решения?

Вот мой Run раздел:

[Run] 
Filename: "{app}\{#MyAppExeName}"; Parameters: "/verysilent /group=""{groupname}\Macrowire 2.5 Pro"" /mergetasks=""desktopicon,file_association"""; Flags: nowait postinstall; Description: "{cm:LaunchProgram,{#StringChange(MyAppName, '&', '&&')}}"; StatusMsg: "Installing Macrowire 2.5 Pro..." 

Вот мой Pascal код:

function PrepareToInstall(var NeedsRestart: Boolean): String; 
var 
    ResultCode: integer; 
begin 
    ... 
    if IsComponentSelected('Macrowire') or IsComponentSelected('Full') then 
    begin 
    ShellExec('', ExpandConstant('{app}\MacroWire 2.5 Pro.msi'), '', '', SW_SHOW, ewWaitUntilTerminated, ResultCode) 
    end; 
    ... 
end; 

Answer 1

Вы, вероятно, хотите, чтобы прервать установку, когда зависимость не удается установить:

function PrepareToInstall(var NeedsRestart: Boolean): String; 
var 
    ResultCode: integer; 
begin 
    ... 
    if IsComponentSelected('Macrowire') or IsComponentSelected('Full') then 
    begin 
    { Using Exec, the ShellExec is an overkill } 
    Exec(ExpandConstant('{app}\MacroWire 2.5 Pro.msi'), '', '', SW_SHOW, 
     ewWaitUntilTerminated, ResultCode); 
    if not FileExists(ExpandConstant('{app}\{#MyAppExeName}')) then 
    begin 
     Result := 'Failed to install MacroWire'; 
     Exit; 
    end; 
    end; 
    ... 
end; 

---

Если вы хотите, чтобы продолжить установку, но вам просто нужно пропустить [Run] запись, используйте Check parameter:

[Run] 
Filename: "{app}\{#MyAppExeName}"; Parameters: "..."; Flags: nowait postinstall; \ 
    Description: "..."; Check: FileExists(ExpandConstant('{app}\{#MyAppExeName}')) 

---

Btw, параметр StatusMsg не используется postinstall записей. И я до сих пор не уверен, применимы ли для этой программы установщики Parameters.