Excel VBA скопировать столбец в существующую книгу

Question

Я имею Workbook, source.xlsm, Worksheet "test1" Колонка A6: A20, что мне нужно скопировать в другой книге, расположенной на моем C: ... по имени Dest .xlsx, Рабочий лист "Активы", Столбец "I". Мне нужно иметь возможность копировать данные и иметь возможность добавлять их в столбец, не перезаписывая ранее скопированные данные. Любая помощь будет спасателем жизни.

Sub Align() 
    Dim TargetSh As String 

    TargetSh = "Assets" 

    For Each WSheet In Application.Worksheets 

     If WSheet.Name <> TargetSh Then 
      WSheet.Select 
      Range("A6:A20").Select 
      Range(Selection, ActiveCell.SpecialCells(xlLastCell)).Select 
      Selection.Copy 
      Sheets(TargetSh).Select 
      lastRow = Range("I65532").End(xlUp).Row 
      Cells(lastRow + 1, 1).Select 
      ActiveSheet.Paste 
     End If 
    Next WSheet 
End Sub 

Answer 1

Это то, что вы пытаетесь? У меня не проверен это, но я думаю, что он должен работать. Дайте мне знать, если вы получите какие-либо ошибки.

Sub Sample_Copy() 
    Dim wb As Workbook, wbTemp As Workbook 
    Dim ws As Worksheet, wsTemp As Worksheet 
    Dim lastRow As Long 

    Set wb = ThisWorkbook 
    Set ws = wb.Sheets("test1") 

    '~~> Change path as applicable 
    Set wbTemp = Workbooks.Open("C:\dest.xlsx") 
    Set wsTemp = wbTemp.Sheets("Assets") 

    lastRow = wsTemp.Range("I" & Rows.Count).End(xlUp).Row + 1 

    ws.Range("A6:A20").Copy wsTemp.Range("I" & lastRow) 

    Application.CutCopyMode = False 

    '~~> Cleanup 
    wbTemp.Close savechanges:=True 
    Set wb = Nothing: Set wbTemp = Nothing 
    Set ws = Nothing: Set wsTemp = Nothing 
End Sub 

НТН

Sid