Applescript Возвращаемый текст не разбивается

Question

Ive играл с applescript около 2 недель, но я столкнулся с проблемой Im пытается создать applescript, который читает все имена папок на нашем сервере. Затем отображает их в выпадающем меню, чтобы я мог выбрать клиента. Проблема заключается в том, что она отображает результат как один вариант выбора в качестве большого предложения и не отделяет каждого клиента, поэтому их можно выбирать индивидуально. до сих пор у меня есть:

set theFolder to alias "server:" 
tell application "Finder" 
    set theText to name of theFolder & return 
    set k to 0 
    repeat with thisSubfolder in (get folders of theFolder) 
     set k to k + 1 
     set theText to theText & name of thisSubfolder & return 
    end repeat 
end tell 
set l to {theText} 
set l2 to "" 
repeat with i in l 
    set l2 to l2 & quoted form of i & " " 
end repeat 
do shell script "/Applications/CocoaDialog.app/Contents/MacOS/CocoaDialog \\ 
    standard-dropdown --title Title --text Text --items " & l2 
set {button, answer} to paragraphs of result 
if button is 1 then 
    return item {answer + 1} of l 
end if 

Большое спасибо

D

Answer 1

Когда вы сделаете это:

set l to {theText} 

Вы просто создать список одного элемента (ваша строка), что означает, что вы в конечном итоге с этим:

{"theFolder 
folder1 
folder2 
folder3 
"} 

Вы тогда повторяясь в этом «списке», пытаясь добавить пробелы между элементами. Но у вас нет списка на самом деле. У вас есть один список элементов с строками с разделителями с возвратом.

Лучший способ получить список имен папок - получить их от System Events. Обратите внимание, что в этом случае вам нужно создать список с именем первой папки в качестве единственного элемента. В противном случае операция & объединяет все вместе как строку, а не создает список.

tell application "System Events" 
    set l to (name of theFolder as list) & name of folders of theFolder 
end tell 

Есть также некоторые синтаксические вопросы, которые болят потом:

1 = "1"

CocoaDialog возвращает строку с номером кнопки: "1". Вы используете if button is 1. Для равенства это должно быть if button is "1".

Скобки используются для группировки, не скобки

Если кнопка "1", вы возвращаете item {answer + 1} of l. Я обвиняю Applescript за то, что разрешил эту работу, когда это не должно. Фактически вы создаете список с номером, который затем принуждается Applescript для индекса списка.Вот все шаги, при условии, answer 0:

1. item {answer + 1} of l получает превратился в
2. item {1} of {folder1, folder2, folder3}
3. Applescript принуждают к item 1 of {folder1, folder2, folder3}
4. Возвращаемое значение: folder1

Вот полностью обновлен версия вашего скрипта:

set theFolder to alias "server:" 
tell application "System Events" 
    set l to {name of theFolder} & name of folders of theFolder 
end tell 

set args to "" 
repeat with i from 1 to (count l) 
    set args to args & quoted form of item i of l 
    if i < (count l) then 
     set args to args & " " 
    end if 
end repeat 

do shell script "/Applications/CocoaDialog.app/Contents/MacOS/CocoaDialog \\ 
    standard-dropdown --title Title --text Text --items " & args 

set {button, answer} to paragraphs of result 
if button is "1" then 
    return item (answer + 1) of l 
end if 

Answer 2

Измените строку:

set l to {theText} 

к:

set l to paragraphs of theText 

, и вы должны быть хорошо идти.