Использование Coldfusion, как определить, будет ли данный временной интервал в рабочее время (другой временной интервал)?

Question

Учитывая, что определенный бизнес открыт с 8 до 17 часов вечера, как лучше всего проверить, что данный промежуток времени попадает в этот диапазон? Дата не имеет значения, просто нужно подтвердить, что весь запрошенный временной диапазон попадает в рабочее время.

Вот мои данные для примера, которые я должен начать. (Я использую cfscript здесь просто быть кратким)

<cfscript> 
    // array of given timeslots to test 
    timeslots = arrayNew(1); 

    // 1st appointment, entirely within normal business hours 
    appointment = structNew(); 
    appointment.begin = "10:00 AM"; 
    appointment.end = "2:00 PM"; 

    arrayAppend(timeslots, appointment); 

    // 2nd appointment, outside of normal business hours 
    appointment = structNew(); 
    appointment.begin = "7:00 PM"; 
    appointment.end = "9:00 PM"; 

    arrayAppend(timeslots, appointment); 

    // 3rd appointment, kind of tricky, partly within business hours, still should fail 
    appointment = structNew(); 
    appointment.begin = "3:00 PM"; 
    appointment.end = "6:00 PM"; 

    arrayAppend(timeslots, appointment); 

    </cfscript> 

Теперь я перебираем этот массив запустить функцию проверки на каждую структуру. Ради примера, это может выглядеть следующим образом:

<cfoutput> 
<cfloop array="#timeslots#" index="i"> 
    <!--- Should return 'true' or 'false' for each item ---> 
    #myValidator(i.begin, i.end)#<br /> 
</cfloop> 
</cfoutput> 

... Так что обратно в реальный вопрос ... как я использую Coldfusion сравнивать те времена с заданными рабочими часами?

<cfscript> 
// if input data is outside of the internal time range, return false, otherwise true 
function myValidator(begin, end) { 
    var businessStart = "8:00 AM"; 
    var businessEnd = "5:00 PM"; 
    var result = false; 

    // what kind of tests do I put here to compare the times? 
} 
</cfscript> 

UPDATE: мое решение - переписывание myValidator сверху на основе обратной связи Бен Гибели и kevink.

// checks if any scheduled events fall outside business hours 
function duringBusinessHours(startTime, endTime) { 
    var result = true; 
    var busStart = 800; 
    var busEnd = 1700; 
    var startNum = 0; 
    var endNum = 0; 

    // convert time string into a simple number: 
    // "7:00 AM" -> 700 | "3:00 PM" -> 1500 
    startNum = timeFormat(arguments.startTime, "Hmm"); 
    endNum = timeFormat(arguments.endTime, "Hmm"); 

    // start time must be smaller than end time 
    if (startNum GTE endNum) { 
     result = false; 

    // If start time is outside of business hours, fail 
    } else if (startNum LT busStart OR startNum GT busEnd) { 
     result = false; 

    // If end time is outside of business hours, fail 
    } else if (endNum LT busStart OR endNum GT busEnd) { 
     result = false; 
    } 
    return result; 
} 

Answer 1

Если вы не заботитесь о днях использовать 24-часовые часы, относиться ко всему, как простое число, и просто использовать больше, меньше, чем ...

<cfif arguments.startime LT bizStart OR arguments.endtime GT bizEnd> 
    <cfreturn false> 
<cfelse> 
    <cfreturn true> 
</cfif> 

Answer 2

Лично я создал два объекта даты, используя CreateDateTime с таким же м/д/г значений и сравнили их, так как CF может сделать это правильно.

Answer 3

Вы определенно хотите создать дату/время с CreateDateTime, а затем сравнить даты и временные рамки таким образом. Если вы принимаете ввод в виде строки с веб-страницы, вы можете использовать ParseDateTime для преобразования строки, представляющей действительный формат даты/времени, в объект даты/времени.