Как создать значение по умолчанию для аргумента функции в Clojure

Question

Я пришел с этим:

 
(defn string->integer [str & [base]] 
    (Integer/parseInt str (if (nil? base) 10 base))) 

(string->integer "10") 
(string->integer "FF" 16) 

Но это должно быть лучшим способом сделать это.

Answer 1

Функция может иметь несколько подписей, если подписи различаются по arity. Вы можете использовать это для предоставления значений по умолчанию.

(defn string->integer 
    ([s] (string->integer s 10)) 
    ([s base] (Integer/parseInt s base))) 

Обратите внимание, что при условии false и nil оба считаются не значения, (if (nil? base) 10 base) может быть сокращен до (if base base 10), или, кроме того, чтобы (or base 10).

Answer 2

Вы также можете разрушить аргументы rest как карты, так как Clojure 1.2 [ref]. Это позволяет назвать и предоставлять по умолчанию для функции аргументов:

(defn string->integer [s & {:keys [base] :or {base 10}}] 
    (Integer/parseInt s base)) 

Теперь вы можете позвонить

(string->integer "11") 
=> 11 

или

(string->integer "11" :base 8) 
=> 9 

Вы можете увидеть это в действии здесь: https://github.com/Raynes/clavatar/blob/master/src/clavatar/core.clj (к примеру)

Answer 3

Данное решение является ближе к дух исходного раствора, но незначительно уборщика

(defn string->integer [str & [base]] 
    (Integer/parseInt str (or base 10))) 

Аналогичная картина, который может быть удобно использование or в сочетании с let

(defn string->integer [str & [base]] 
    (let [base (or base 10)] 
    (Integer/parseInt str base))) 

В то время как в этом случае более развернутого, он может быть полезен если вы хотите иметь значения по умолчанию в зависимости от других входных значений. Например, рассмотрим следующую функцию:

(defn exemplar [a & [b c]] 
    (let [b (or b 5) 
     c (or c (* 7 b))] 
    ;; or whatever yer actual code might be... 
    (println a b c))) 

(exemplar 3) => 3 5 35 

Этот подход может быть легко расширен для работы с именованными аргументами (как в растворе М. Gilliar в), а также:

(defn exemplar [a & {:keys [b c]}] 
    (let [b (or b 5) 
     c (or c (* 7 b))] 
    (println a b c))) 

Или используя еще от слияния:

(defn exemplar [a & {:keys [b c] :or {b 5}}] 
    (let [c (or c (* 7 b))] 
    (println a b c))) 

Answer 4

Существует другой подход вы, возможно, захотите рассмотреть следующие вопросы: partial функции. Это, возможно, более «функциональный» и более гибкий способ указания значений по умолчанию для функций.

Начните с создания (при необходимости) функцию, которая имеет параметр (ы), которые вы хотите предоставить по умолчанию (ы) в качестве ведущего параметра (ов):

(defn string->integer [base str] 
    (Integer/parseInt str base)) 

Это сделано потому, что Clojure-х версия partial позволяет вам указывать значения по умолчанию только в том порядке, в котором они отображаются в определении функции.После того как параметры были заказаны по желанию, вы можете создать версию функции «по умолчанию» с помощью partial функции:

(partial string->integer 10) 

Для того, чтобы сделать эту функцию вызываемые несколько раз, вы можете поместить его в вар, используя def:

(def decimal (partial string->integer 10)) 
(decimal "10") 
;10 

Вы также можете создать "локальный" по умолчанию с помощью let:

(let [hex (partial string->integer 16)] 
    (* (hex "FF") (hex "AA"))) 
;43350 

Частичный функциональный подход имеет одно ключевое преимущество перед другими: потребитель функции все еще может решить, чем будет использоваться значение по умолчанию, а не функции без необходимости изменять определение функции. Это проиллюстрировано в примере с помощью hex, где я решил, что функция по умолчанию decimal не то, что я хочу.

Другим преимуществом такого подхода является назначение функции по умолчанию другим именем (десятичным, шестнадцатеричным и т. Д.), Которое может быть более наглядным и/или другим областью (var, local). Частичная функция также может быть смешан с некоторыми из подходов выше, при желании:

(defn string->integer 
    ([s] (string->integer s 10)) 
    ([base s] (Integer/parseInt s base))) 

(def hex (partial string->integer 16)) 

(Обратите внимание, это немного отличается от ответа Брайана, как порядок параметров был отменен по причинам, указанным в верхней части этого ответ)

Answer 5

Вы также можете посмотреть в (fnil)https://clojuredocs.org/clojure.core/fnil