Проблем с Applicative стилем Parsec

Question

У меня есть следующий ADT:

type Program = [Expr] 
data Expr = 
    Num Int 
    | Bool Bool 
    | Binding String Expr 
    deriving (Show) 

Вот анализатор для переменных связывания выражений вида lhs is rhs.

binding :: Parser Expr 
binding = do 
    lhs <- word 
    spaces 
    string "is" 
    spaces 
    rhs <- expr 
    return $ Binding lhs rhs 

Это прекрасно работает, но когда я пытаюсь преобразовать его в аппликативный стиль, это дает неверный результат.

binding :: Parser Expr 
binding = Binding <$> word <* (spaces *> string "is" *> spaces) *> expr 

*> Замена с >> в скобках, часть не работает. В чем разница между этими двумя реализациями? Есть ли комбинатор для составления двух парсеров и игнорирования результата обоих?

Попытка отладки с Debug.trace тоже не работала ... Ничего не было напечатано.

binding :: Parser Expr 
binding = (\x y -> trace (show (x, y)) (Binding x y)) <$> word <* (spaces *> string "is" *> spaces) *> expr 

Остальная часть синтаксического анализа, для контекста:

word :: Parser String 
word = many1 letter 

expr :: Parser Expr 
expr = binding <|> atom 

program :: Parser Program 
program = do 
    spaces 
    result <- many (expr <* spaces) 
    return result 

Answer 1

Ваша проблема в том, что <$> и <*> и т. Д. Оставлены ассоциативными. Это означает, что ваша линия:

binding = Binding <$> word <* (spaces *> string "is" *> spaces) *> expr 

будет интерпретироваться как

binding = (Binding <$> word <* (spaces *> string "is" *> spaces)) *> expr 

Это означает, что он будет анализировать, а затем игнорировать все до последнего выраж. Как @icktoofay сказал, вы можете написать предполагаемую версию, как:

binding = Binding <$> word <* spaces <* string "is" <* spaces <*> expr 

и не нужны никакие скобки вообще, из-за левоассоциативность.

Answer 2

@danem правильно, попробуйте:

binding :: Parser Expr 
binding = Binding <$> word <*> (spaces *> string "is" *> spaces *> expr) 

Полный источник: http://lpaste.net/121011

Ваше первоначальное определение разборе таким образом:

binding = ((Binding <$> word) <* (spaces *> string "is" *> spaces)) *> expr 

т. Е. Имеет форму something *> expr, и поэтому возвращаемое значение определяется исключительно последним expr. Маркер lhs и is разобран, но затем отбрасывается.

Вот как проверить тип подвыражения:

Binding      :: String -> Expr -> Expr 
(Binding <$> word)   :: Parser (Expr -> Expr) 
(Binding <$> word) <* (...) :: Parser (Expr -> Expr) 

Итак, мы видим, что все проверки типа из-за выделки и тот факт, что мы отбрасывая результат something.