изменить макет подсказки cmd

Question

Я хочу изменить макет командной строки через командный файл. Его нужно отображать в центре или в каком-либо месте экрана, но не на самом верху. Я пробовал:

@echo off 
COLOR 8f 
mode con:cols=80 lines=40 
mode con:top=10 

mode con:cols=80 lines=40 Команда работает, но mode con:top=10 нет.
Пожалуйста, предложите мне право на это.

Answer 1

Чтобы управлять свойствами окна, вы должны

1. создать профиль в реестре под некоторым названием. Windows использует реестр для хранения настроек для окон командной строки на основе заголовка окна.

2. открыть окно с заголовком, который соответствует той, которая используется в профиле

Используйте следующий код в качестве образца, чтобы вы начали.

@echo off 
setlocal 
set mycmdTitle=My Special Command Prompt 
Set mycmdHeight=40 
Set mycmdWidth=80 
Set mycmdBufferHeight=500 
Set mycmdBufferWidth=%mycmdWidth% 
Set mycmdxPos=0 
Set mycmdyPos=120 
Set mycmdColor=8f 
Set /A mycmdBufferSize=mycmdBufferHeight*0x10000+mycmdBufferWidth 
Set /A mycmdWindowPos=mycmdyPos*0x10000+mycmdxPos 
Set /A mycmdWindowSize=mycmdHeight*0x10000+mycmdWidth 
Set mycmdCmd=Title My First Command Prompt^&Echo.^&Echo.^&Echo.^&Echo. 
Call :StartCommandPrompt %mycmdBufferSize% %mycmdColor% %mycmdWindowPos% %mycmdWindowSize% "%mycmdTitle%" "%mycmdCMD%" 
endlocal 
Goto :EOF 

:StartCommandPrompt 
REM receives %1=BufferSize %2=Color %3=WindowPos %4=WindowSize %5=Title %6=cmd 
reg add "HKCU\Console\%~5" /V ScreenBufferSize /T REG_DWORD /D %1 /F >nul 
reg add "HKCU\Console\%~5" /V ScreenColors /T REG_DWORD /D 0x%2 /F >nul 
reg add "HKCU\Console\%~5" /V WindowPosition /T REG_DWORD /D %3 /F >nul 
reg add "HKCU\Console\%~5" /V WindowSize /T REG_DWORD /D %4 /F >nul 
start "%~5" %COMSPEC% /K %6 
goto :eof 

Этот код основан на какой-то оригинальный код, который я когда-то нашел на Google, но я не могу получить его, так что я не могу дать надлежащее приписывание к первоначальному разработчику.