Предложение по временной сетке?

Question

В VB.NET Я ищу построить «Time» сетку, очень похожую на Restriction сетке времени родительской секции Windows: http://www.thinkbroadband.com/images/guides/time-restrictions.png

Это необходимо для переключения между 2-х цветов на ячейку щелкните

Я играл с One-Cell = One-Label, и это работает, но, как и сетка Windows Time Restriction, я бы хотел, чтобы метки меняли цвета, если я перехожу по метке , пока с левой кнопкой нажата (и не только на этикетке).

Вот что я в настоящее время:

Private Sub ColorToggle(sender As Object, e As MouseEventArgs) Handles Label1.Click, Label2.Click, Label3.Click 'etc.. 
    If e.Button = Windows.Forms.MouseButtons.Left Then 
     sender.backcolor = If(sender.backcolor = SystemColors.Control, Color.LightGreen, SystemColors.Control) 
    End If 
End Sub 

Поскольку отправитель остается такой же, когда я парить метки (отправитель = метка я изначально нажал на), этот код не работает для моей цели ,

Я ищу предложения!

Спасибо :)

Answer 1

При нажатии на кнопку управления и удерживать кнопку мыши, этот элемент управления фиксирует следующие события мыши, так что вы не будете получать события от других ярлыках, лейблах при перемещении мыши их.

Хитрость заключается в установке label.Capture = False.

Позволяет определить цвета:

Private ReadOnly selectedColor As Color = Color.Blue 
Private ReadOnly unselectedColor As Color = Color.White 

И Booleans сохранения текущего состояния наших операций

Private isSelecting As Boolean = False 
Private isUnselecting As Boolean = False 

(Все четыре, как поля класса формы)

Теперь давайте писать эти три обработчики событий:

Private Sub Label_MouseDown(sender As Object, e As EventArgs) 
    'This event starts selecting/unselecting 

    Dim label = DirectCast(sender, Label) 
    label.Capture = False '<=== THIS IS IMPORTANT! 
    If label.BackColor = selectedColor Then 
     isUnselecting = True 
    Else 
     isSelecting = True 
    End If 
    SelectLabel(label) 
End Sub 

Private Sub Label_MouseUp(sender As Object, e As EventArgs) 
    'This event stops selecting/unselecting 

    isSelecting = False 
    isUnselecting = False 
End Sub 

Private Sub Label_MouseEnter(sender As Object, e As EventArgs) 
    SelectLabel(DirectCast(sender, Label)) 
End Sub 

И нам нужна эта процедура, которая выбирает или отменялся метки:

Private Sub SelectLabel(label As Label) 
    If isSelecting Then 
     label.BackColor = selectedColor 
    ElseIf isUnselecting Then 
     label.BackColor = unselectedColor 
    End If 
End Sub 

Вот оно!

---

Сноска: Я создал Lables так:

Private Sub Form_Load(sender As Object, e As EventArgs) Handles MyBase.Load 
    Const w As Integer = 50, h As Integer = 50 

    For x = 1 To 10 
     For y = 1 To 10 
      Dim lbl As New Label() With { 
       .Location = New Point(x * w, y * h), 
       .Size = New Size(w, h), 
       .BorderStyle = BorderStyle.FixedSingle, 
       .BackColor = unselectedColor 
      } 
      AddHandler lbl.MouseDown, AddressOf Label_MouseDown 
      AddHandler lbl.MouseUp, AddressOf Label_MouseUp 
      AddHandler lbl.MouseEnter, AddressOf Label_MouseEnter 
      Controls.Add(lbl) 
     Next 
    Next 
End Sub 

Answer 2

Я надеюсь, что это не домашнее задание ...

Private Sub Button8_Click(sender As Object, e As EventArgs) Handles Button8.Click 
    Dim i As Integer 
    With dgv 
     .ColumnCount = 0 
     .DataSource = Nothing 
     .Columns.Add("Day", "Day") 
     For i = 0 To 23 
      .Columns.Add(i, i) 
      .Columns(.Columns.Count - 1).Width = 30 
     Next 
     For i = 1 To 7 
      .Rows.Add({i}) 
     Next 

    End With 
End Sub 

Private Sub dgv_CellClick(sender As Object, e As DataGridViewCellEventArgs) Handles dgv.CellClick 
    dgv.CurrentCell.Style.BackColor = Color.Blue 
End Sub 

---

Вот перетаскивание версия:

Private Sub dgv_MouseUp(sender As Object, e As MouseEventArgs) Handles dgv.MouseUp 
    For Each cell As DataGridViewCell In dgv.SelectedCells 
     If cell.Style.BackColor = Color.Blue Then 
      cell.Style.BackColor = Color.White 
     Else 
      cell.Style.BackColor = Color.Blue 
     End If 
    Next 
    dgv.ClearSelection() 
End Sub