Цветные несмежные ячейки, соответствующие критериям

Question

Я использую приведенный ниже код, чтобы покрасить ячейки в столбцах K и Z, соответствующие критериям; но он окрашивает все ячейки между K и Z. Чтобы исправить, я использую последнюю строку кода, чтобы удалить цвет в столбцах L через Y. Есть ли способ изменить строку кода, которая начинается с «Range», только для цветных ячеек K и Z, которые соответствуют критериям?

Sub ColrCls() 
    Dim ws As Worksheet 
    Dim lRow As Long, i As Long 

    Set ws = ThisWorkbook.Sheets("Sheet1") 

    With ws 
     lRow = .Range("K" & .Rows.Count).End(xlUp).Row 

     For i = 2 To lRow 
      If .Cells(i, 11).Value = "Non Sen" And .Cells(i, 26).Value = "N/A" Then 
      Range(.Cells(i, 11), .Cells(i, 26)).Interior.ColorIndex = 6 
      End If 
     Next i 

     Columns("L:Y").Interior.ColorIndex = xlNone 
    End With 
End Sub 

Answer 1

Вы с указанием Range.Parent property в вашем With ... End With statement но игнорируя его, когда это большинство important¹.

Sub ColrCls() 

    Dim ws As Worksheet 
    Dim lRow As Long, i As Long 

    Set ws = ThisWorkbook.Sheets("Sheet1") 

    With ws 
     lRow = .Range("K" & .Rows.Count).End(xlUp).Row 

     For i = 2 To lRow 
      If .Cells(i, 11).Value = "Non Sen" And .Cells(i, 26).Value = "N/A" Then 
       .Range("K" & i & ", Z" & i).Interior.ColorIndex = 6 
      Else 
       .Range("K" & i & ", Z" & i).Interior.Pattern = xlNone 
      End If 
     Next i 
    End With 
End Sub 

A Range object к Union несмежных клетки могут быть одним из следующих.

.Range("K5, Z5") 
Union(.Cells(5, "K"), .Cells(5, "Z")) 

В приведенном выше примере я объединил строку, подобную первому из этих двух примеров.

---

¹ _{См Is the . in .Range necessary when defined by .Cells? для серьезного обсуждения по этому вопросу.}

Answer 2

Вы могли бы заменить

Range(.Cells(i, 11), .Cells(i, 26)).Interior.ColorIndex = 6 

с

.Cells(i, 11).Interior.ColorIndex = 6 
.Cells(i, 26).Interior.ColorIndex = 6