XSLT: создать новый уникальный идентификатор int для элемента

Question

Я должен обновить XML с помощью XSLT.

Мой предыдущий элемент XML имеет некоторый элемент с атрибутом Id с значением int. Некоторый элемент не имеет этого Id, поскольку на них нельзя ссылаться ни на один другой элемент.

XML Пример:

<Object Id="12359" Type="TypeX"> 
<Object Type="TypeA"> 
    <SomeOtherObject Id="112" Type="TypeV"/> 
</Object> 
<SomeOtherOtherObject Id="1596" Type="TypeM"/> 
</Object> 

Для одного конкретного пункта (который можно легко управлять, чтобы выбрать с запросом XPATH, я хочу, чтобы создать новый идентификатор, который не используется какой-либо другой элемент

.

Может ли это быть сделано с помощью XSLT

у меня уже есть ключ:

<xsl:key name="node-reference-key" match="*[@Id]" use="@Id" /> 

И я могу выбрать элемент, который имеет недостающий свойство как это:

<xsl:template match="*[@Type='TypeA']"> 

Это будет выполняться с помощью C# приложения, но я хотел бы избежать любой ценой любой C# код.

Answer 1

Вы не можете изменять переменные в XSLT, поэтому установка глобальной переменной и увеличение ее по мере того, как вы собираетесь отслеживать следующий уникальный идентификатор, невозможно.

Но вы могли бы сделать это:

• выбрать максимальный идентификатор в документе:

  <xsl:variable name="max-id" select="//@Id[not(. &lt; //@Id)]" /> 
  

• создать разделенный запятыми список уникальных идентификаторов элементов (с помощью generate-id()) и именованный шаблон:

  <xsl:variable name="missing-list"> 
      <xsl:call-template name="list-ids"> 
      <xsl:with-param name="nodes" select="//*[not(@Id)]" /> 
      </xsl:call-tempalte> 
  </xsl:variable> 
  
  <!-- and --> 
  
  <xsl:template name="list-ids"> 
      <xsl:param name="nodes" /> 
      <xsl:for-each select="$nodes"> 
      <xsl:value-of select="concat(generate-id(), ',')" /> 
      </xsl:for-each> 
  </xsl:template> 
  

• Используйте это в качестве контрольной точки. Для любого заданного элемента (который не имеет @Id), новый уникальный идентификатор станет $max-id плюс свою позицию в этом списке (вы можете получить, что с substring-before($missing-list, generate-id()), чтобы получить позицию мы считаем запятые:

  <xsl:variable name="pos" select=" 
      string-length($preceding-ids) 
      - string-length(translate($preceding-ids, ',', '')) 
  "/> 
  
  <xsl:attribute name="Id"> 
      <xsl:value-of select="$max-id + $pos + 1" /> 
  </xsl:attribute> 
  

Так, вместе взятое это выглядит следующим образом:

<xsl:transform xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0"> 
    <xsl:output encoding="UTF-8" indent="yes" /> 

    <xsl:variable name="max-id" select="//@Id[not(. &lt; //@Id)]" /> 

    <xsl:variable name="missing-list"> 
     <xsl:call-template name="list-ids"> 
     <xsl:with-param name="nodes" select="//*[not(@Id)]" /> 
     </xsl:call-template> 
    </xsl:variable> 

    <xsl:template match="@*|node()"> 
     <xsl:copy> 
     <xsl:apply-templates select="@*|node()"/> 
     </xsl:copy> 
    </xsl:template> 

    <xsl:template match="*[not(@Id)]"> 
     <xsl:copy> 
     <xsl:apply-templates select="@*" /> 

     <xsl:variable name="preceding-ids" select=" 
      substring-before($missing-list, generate-id()) 
     "/> 
     <xsl:variable name="pos" select=" 
      string-length($preceding-ids) 
      - string-length(translate($preceding-ids, ',', '')) 
     "/> 

     <xsl:attribute name="Id"> 
      <xsl:value-of select="$max-id + $pos + 1" /> 
     </xsl:attribute> 

     <xsl:apply-templates select="node()" /> 
     </xsl:copy> 
    </xsl:template> 

    <xsl:template name="list-ids"> 
     <xsl:param name="nodes" /> 
     <xsl:for-each select="$nodes"> 
     <xsl:value-of select="concat(generate-id(), ',')" /> 
     </xsl:for-each> 
    </xsl:template>   
</xsl:transform>