Пакетный уровень ошибок не работает должным образом

Question

поэтому у меня действительно проблемы с ERRORLEVEL партии. Это просто не работает для меня. У меня есть собственный собственный скрипт для сборки ms и я всегда получаю 0 обратно от ERRORLEVEL, независимо от того, что я делаю (например, msbuild, tf get, tf checkout, copy, xcopy, ...)

поэтому я сделал небольшой пример, чтобы разместить его здесь:

@echo off 
set Update=1 
IF %Update% == 1 (
    echo. 
    set /p "=- Copy stuff..." <NUL 
    xcopy /R /Y C:\test\2.lib C:\test1 
    if %ERRORLEVEL% neq 0 (echo FAILED!) ELSE (echo SUCCEED!) 
    echo -^> done 
    pause 
) 

поэтому его всегда возвращаются успеха и печати 0, когда я делаю: эхо% ERRORLEVEL%

пожалуйста, вы можете помочь мне с этим? Я действительно хотел бы использовать эту ErrorLevel

Answer 1

вам нужно delayed expansion здесь или использовать IF ERRORLEVEL:

@echo off 
set Update=1 
IF %Update% == 1 (
    echo. 
    set /p "=- Copy stuff..." <NUL 
    xcopy /R /Y C:\test\2.lib C:\test1 
    IF ERRORLEVEL 1 (echo FAILED!) ELSE (echo SUCCEED!) 
    echo -^> done 
    pause 
) 

с IF ERRORLEVEL 1 вы можете проверить, если Равен 1 или больше.

Answer 2

Как говорит npocmaka, у вас есть проблема с задержкой расширения.

Альтернативой является толкать ERRORLEVEL и вместо этого использовать операторы конкатенации условных команд && и.

@echo off 
set Update=1 
IF %Update% == 1 (
    echo. 
    set /p "=- Copy stuff..." <NUL 
    xcopy /R /Y C:\test\2.lib C:\test1 && (echo SUCCEED!) || (echo FAILED!) 
    echo -^> done 
    pause 
) 

Edit показывает использование нескольких линий

@echo off 
set Update=1 
IF %Update% == 1 (
    echo. 
    set /p "=- Copy stuff..." <NUL 
    xcopy /R /Y C:\test\2.lib C:\test1 && (
     echo First success command 
     echo SUCCEED! 
    ) || (
     echo First failure command 
     echo FAILED! 
    ) 
    echo -^> done 
    pause 
)