Простой способ фильтрации списка карт по значениям ключей в Clojure

Question

Я не могу найти встроенные функции в Clojure для фильтрации списка карт по значениям ключей. Например, у нас есть следующий список:

user=> (def animals (list {:name "Charlie" :weight 350 :specie :elephant} 
          {:name "Vasya" :weight 250 :specie :bear} 
          {:name "John" :weight 200 :specie :elephant} 
          {:name "Monk" :weight 200 :specie :monkey})) 
#'user/animals 

И я хочу, чтобы выбрать, например, все :specie со значением :elephant. Как я могу это сделать? Лучший способ узнать это:

user=> (defn filter-data [data m] 
     (let [k (keys m) v (vals m)] 
      (filter #(= (map % k) v) data))) 
#'user/filter-data 

user=> (clojure.pprint/print-table (filter-data animals {:specie :elephant})) 

| :name | :weight | :specie | 
|---------+---------+-----------| 
| Charlie |  350 | :elephant | 
| John |  200 | :elephant | 
nil 

Есть ли лучший способ сделать это?

Answer 1

Это может быть легко достигнуто с фильтром

(clojure.pprint/print-table 
    (filter #(= (:specie %) :elephant) animals)) 

вы всегда можете обернуть фильтр в функции, чтобы получить различные «синтаксис», такие как:

(defn cool-filter [[k v] l] 
    (filter #(= (k %) v) l)) 

(clojure.pprint/print-table 
    (cool-filter [:specie :elephant] animals)) 

Answer 2

Хотя filter решение, очевидно, наиболее прямолинейный, я бы хотел добавить альтернативу, если вам нужно искать более одного вида:

(def grouped-animals (group-by :specie animals)) 
(:elephant grouped-animals) 
; [{:name "Charlie", :weight 350, :specie :elephant} {:name "John", :weight 200, :specie :elephant}] 

Answer 3

Вы также можете использовать функцию состав:

(filter (comp (partial = :elephant) :specie) animals) 

или ...

(filter (comp #{:elephant} :specie) animals)