Удаление коллекций кнопок VBA

Question

Я использую следующий скрипт для создания кнопок в excel, диапазон - именно там, где я бы хотел его разместить.

Sub CreateAddButton(rng As Range) 
    Dim btn As Button 
    With Worksheets("User") 
     Set btn = .Buttons.Add(rng.Left, rng.Top, rng.width, rng.Height) 
     With btn 
      .name = "Add" 
      .Caption = "Add Column" 
      .OnAction = "CreateVariable" 
     End With 
    End With 
End Sub 

Проблема только в том, что мне нужен метод, который может удалить все кнопки, созданные этим методом? Я хочу, если это возможно, избегать глобальных переменных. Любая помощь будет получена с благодарностью. James

Answer 1

Я бы предложил метод Тима с использованием определенного имени - для которого не требуется глобальная переменная. Например, вы могли бы добавить «_ || ForDeletion» суффикс к каждому имени кнопки, а затем искать его на удаление рутина

.Name = "Add_||ForDeletion" 

Forms кнопка не предусматривает другой вариант, хотя (не каламбур), вы может хранить текст в AlternativeText в разделе «Свойства», затем «Веб», и использовать его как идентификатор для процедуры удаления.

Функция удаление рутины в нижней части работает в обратном направлении, чтобы избежать ошибок при циклический диапазоном

Sub TesMe() 
    Call CreateAddButton([a2]) 
End Sub 

Sub CreateAddButton(rng As Range) 
    Dim btn As Button 
    With Worksheets("User") 
     Set btn = .Buttons.Add(rng.Left, rng.Top, rng.Width, rng.Height) 
     With btn 
      .Name = "Add" 
      .Caption = "Add Column" 
      .OnAction = "CreateVariable" 
      .ShapeRange.AlternativeText = "MyCollection" 
     End With 
    End With 
End Sub 


Sub GetMyButtons() 
    Dim btns As Object 
    Dim lngRow As Long 
    Set btns = Sheets("User").Buttons 
    For lngRow = btns.Count To 1 Step -1 
     If btns(lngRow).ShapeRange.AlternativeText = "MyCollection" Then 
      MsgBox "Found one", vbCritical 
      btns(lngRow).Delete 
     End If 
    Next 
End Sub 

Answer 2

Кнопки в VBA представлены в коллекции Shapes. Вы можете использовать:

Sub deleteButtons() 
Dim btn As Shape 

For Each btn In ActiveSheet.Shapes 
    If btn.AutoShapeType = msoShapeStyleMixed Then btn.Delete 
Next 

End Sub 

msoShapeStyleMixed кажется тип для всех форм и элементов управления ActiveX.