Цикл нескольких условий

Question

Мне нужен цикл VBScript, требующий ввести целое число от 1 до 10, включая, если неверный символ или номер введен, а затем повторить запрос до тех пор, пока желаемый номер не будет получен от пользователя.

Это то, что я пробовал:

Option Explicit 
Dim Num 

Num=inputbox("Please enter integer number between 1 to 10") 

'Checking if entered value is numeric 
Do while not isnumeric(Num) 
    Num=inputbox("Please enter integer number between 1 to 10", "INCORRECT SYMBOL") 
Loop 

Do while (Num<1 or Num>10) 
    Num=inputbox("Please enter integer number between 1 to 10 ", "Number is NOT IN RANGE") 
Loop 

Do while not int(Num) 
    Num=inputbox("Please enter integer number between 1 to 10 ", "Number is NOT INTEGER") 
Loop 

не работает: когда я вхожу 3, например, я получаю InputBox говоря «номер не INTEGER», при вводе буквы я получаю ошибки типа сообщения о несоответствии строки , код ошибки 800A00D.

Answer 1

Вам нужна одна петля. Для каждого (вариант) входа вам необходимо проверить:

1. это Empty (Пользователь нажал Отмена или X) - Прервать
2. это пустой (нулевой длины или последовательность пробелов) строка
3. является его числовое
4. это целое число
5. он в диапазоне - Принять

как в:

Option Explicit 

Dim vNum, sNum, nNum 
Do 
    vNum = InputBox("Please enter an integer beween 1 and 10 (inclusive)") 
    If IsEmpty(vNum) Then 
     WScript.Echo "Aborted" 
     Exit Do 
    Else 
     sNum = Trim(vNum) 
     If "" = sNum Then 
     WScript.Echo "Empty string" 
     Else 
     If IsNumeric(sNum) Then 
      nNum = CDbl(sNum) 
      If nNum <> Fix(nNum) Then 
       WScript.Echo "Not an Integer" 
      Else 
       If nNum < 1 Or nNum > 10 Then 
        WScript.Echo "Not in range" 
       Else 
        WScript.Echo nNum, "is ok" 
        Exit Do 
       End If 
      End If 
     Else 
      WScript.Echo "Not a number" 
     End If 
     End If 
    End If 
Loop 
WScript.Echo "Done" 

Использование разных переменных для разных типов данных может быть педантичным, но должно показать, почему у вас возникли проблемы с типом.

Ваш

Do while not int(Num) 

не работает, как ожидалось, потому что здесь Num представляет собой число от 1 до 10; округление (не существующей) дробной части дает Num снова; Число, вычисляемое в булевом контексте/как bool, дает (всегда) True.

Update WRT комментарий:

Trim удаляет пространство от головы или хвоста строки; WScript.Echo отправляет вывод в консоль (cscript) или в диалоговое окно (wscript).

Update:

Как this question шоу, я не ясно, что нажав кнопку Отмена или X (Закрыть) устанавливает vNum в пустой вариант, который отличается от пустой/нулевой строки длины. Поэтому его следует рассматривать как указание на намерение пользователей прекратить действие.

BTW: Вам необходимо прочитать Документы, но вы не можете верить им всегда (см. here).