cython статические формы представления массива

Question

В cython можно использовать представления массива, например.

cdef void func(float[:, :] arr) 

В моем использовании второе измерение должно иметь форму 2. Могу ли я сказать cython? Я думал о чем-то вроде:

cdef void func(float[:, 2] arr) 

но это приводит к недопустимому синтаксису; Или возможно иметь что-то более похожее на C++, например.

cdef void func(tuple<float, float>[:] arr) 

Заранее благодарен!

Answer 1

Вместо этого вы можете использовать статический массив 2D. Просто используйте указатель. Вот как вы ее достижения

def pyfunc(): 
    # static 1D array 
    cdef float *arr1d = [1,-1, 0, 2,-1, -1, 4] 
    # static 2D array 
    cdef float[2] *arr2d = [[1,.2.],[3.,4.]] 
    # pass to a "cdef"ed function 
    cfunc(arr2d) 

# your function signature would now look like this 
cdef void cfunc(float[2] *arr2d): 
    print("my 2D static array") 
    print(arr2d[0][0],arr2d[0][1],arr2d[1][0],arr2d[1][1]) 

Назвать это вы получите:

>>> pyfunc() 
my 2D static array 
1.0, 2.0, 3.0, 4.0 

Answer 2

Я не думаю, что это действительно работает, но если вы хотите сделать это, то самый лучший способ, вероятно, использовать memoryviews из structs (которые совместимы с numpys пользовательских dtypes):

import numpy as np 

cdef packed struct Pair1: # packed ensures it matches custom numpy dtypes 
       # (but probably doesn't matter here!) 
    double x 
    double y 

# pair 1 matches arrays of this dtype  
pair_1_dtype = [('x',np.float64), ('y',np.float64)] 

cdef packed struct Pair2: 
    double data[2] 

pair_2_dtype = [('data',np.float64, (2,))] 

def pair_func1(Pair1[::1] x): 
    # do some very basic work 
    cdef Pair1 p 
    cdef Py_ssize_t i 
    p.x = 0; p.y = 0 
    for i in range(x.shape[0]): 
     p.x += x[i].x 
     p.y += x[i].y 

    return p # take advantage of auto-conversion to a dict 

def pair_func2(Pair2[::1] x): 
    # do some very basic work 
    cdef Pair2 p 
    cdef Py_ssize_t i 
    p.data[0] = 0; p.data[1] = 0 
    for i in range(x.shape[0]): 
     p.data[0] += x[i].data[0] 
     p.data[1] += x[i].data[1] 

    return p # take advantage of auto-conversion to a dict 

и функцию, чтобы показать вам, как это назвать:

def call_pair_funcs_example(): 
    # generate data of correct dtype 
    d = np.random.rand(100,2) 
    d1 = d.view(dtype=pair_1_dtype).reshape(-1) 
    print(pair_func1(d1)) 

    d2 = d.view(dtype=pair_2_dtype).reshape(-1) 
    print(pair_func2(d2)) 

---

То, что я хотел бы сделать это:

ctypedef double[2] Pair3 

def pair_func3(Pair3[::1] x): 
    # do some very basic work 
    cdef Pair3 p 
    cdef Py_ssize_t i 
    p[0] = 0; p[1] = 0 
    for i in range(x.shape[0]): 
     p[0] += x[i][0] 
     p[1] += x[i][1] 

    return p # ??? 

Это успешно компилируется, но я не мог найти способ превращения его из NumPy. Если бы вы могли решить, как заставить эту версию работать, я думаю, что это будет самое элегантное решение.

---

Обратите внимание, что я не убежден в преимуществах производительности любого из этих решений. Ваш лучший способ, вероятно, рассказать Cython о том, что конечное измерение смежно в памяти (например, double [:,::1]), но пусть оно будет любого размера.