Excel VBA Коллекции и пользовательские типы данных

Question

Я пытаюсь узнать, как создать пользовательский тип данных, а затем использовать его с коллекцией. Я решил проблему другим способом, но это началось с отчета по расписанию, который я автоматизировал. Я изначально хотел иметь 2-мерный массив с различными типами данных. Когда я не мог этого сделать, некоторые исследования привели к идее сбора пользовательских типов данных. Однако примеры, которые я нашел, продолжают подталкивать меня к созданию класса. Мне это пока не нравится, и похоже, что это должно быть выполнимо. Вот вроде того, что я ищу (я начал с примера, я нашел на этом сайте):

Option Explicit 

'***** User defined type 
Public Type MyType 
    MyInt As Integer 
    MyString As String 
    MyDoubleArr(2) As Double 
End Type 

Public ColThings As Collection 

Sub CollectionTest() 
    Dim x As Integer 
    Dim vrecord As MyType 

    For x = 1 To 4 
     vrecord.MyInt = x 
     vrecord.MyString = "Matt" 
     vrecord.MyDoubleArr(0) = x + 5 
     vrecord.MyDoubleArr(1) = x + 6 
     vrecord.MyDoubleArr(2) = x + 7 
     ColThings.Add vrecord 
    Next x 

    For x = 1 To 4 
    Debug.Assert vrecord.MyInt & " - " & vrecord.MyString & " - " & vrecord.MyDoubleArr(0) & ", " & vrecord.MyDoubleArr(1) & ", " & vrecord.MyDoubleArr(0) 
    Next x 
End Sub 

Ошибки я получаю: Ошибка компиляции: «Только пользовательские типы, определенные в общественных местах объектные модули могут быть принудительно применены к варианту или из него или переданы в функции поздней связи »

Я не новичок с VBA, но я пытаюсь сделать следующий шаг.

Заранее спасибо.

Answer 1

Я принял удар, в конечном счете, я не уверен, что это то, что вы хотите, но если вы не хотите создавать класс, то единственным другим вариантом, который я вижу, является сохранение ваших типов в массиве вместо коллекции. Насколько мне известно (пожалуйста, поправьте меня, если я ошибаюсь) вы не можете добавить определяемый пользователем тип в коллекцию, вы должны создать его как класс, создать экземпляр объекта этого класса, а затем добавить его в коллекцию.

Вместо этого я объявил массив Records() из MyType и добавил каждый MyType к этому массиву.

Option Explicit 

'***** User defined type 
Public Type MyType 
    MyInt As Integer 
    MyString As String 
    MyDoubleArr(2) As Double 
End Type 

Public ColThings As Collection 

Sub CollectionTest() 
    Dim x As Integer 
    Dim Records() As MyType 
    Dim vrecord As MyType 

    For x = 1 To 4 
     vrecord.MyInt = x 
     vrecord.MyString = "Matt" 
     vrecord.MyDoubleArr(0) = x + 5 
     vrecord.MyDoubleArr(1) = x + 6 
     vrecord.MyDoubleArr(2) = x + 7 
     ReDim Preserve Records(x) 
     Records(x) = vrecord 
    Next x 

    For x = 1 To 4 
    Debug.Print Records(x).MyInt & " - " & Records(x).MyString & " - " & Records(x).MyDoubleArr(0) & ", " & Records(x).MyDoubleArr(1) & ", " & Records(x).MyDoubleArr(0) 
    Next x 

End Sub 

Я считаю, что это похоже к тому, что вы хотите достичь. Я еще не пытался метод класса, поскольку вы сказали, что не совсем готовы к этому, но это было бы очень хорошим упражнением по моему скромному мнению.